Найти все MKV, извлечь английские субтитры, удалить все субтитры, удалить оригинальный MKV из удаленных субтитров

Question

Пока что:

@echo off
cls
set rootfolder=C:\
echo Enumerating all MKVs under %rootfolder%
echo.
for /r %rootfolder% %%a in (*.mkv) do (
    for /f %%b in ('mkvmerge --identify-verbose "%%a" ^| find /c /i "subtitles"') do (
        if [%%b]==[0] (
            echo "%%a" has no subtitles
        ) else (
            echo.
            echo "%%a" has subtitles
            mkvmerge -q -o "%%~dpna (No Subs)%%~xa" -S "%%a"
            if errorlevel 1 (
                echo Warnings/errors generated during remuxing, original file not deleted
            ) else (
                del /f "%%a"
                echo Successfully remuxed to "%%~dpna (No Subs)%%~xa", original file deleted
            )
            echo.
        )
    )
)

Который рекурсивно находит все файлы MKV по указанному пути и удаляет все субтитры из найденных файлов MKV (если найденный MKV содержит субтитры), наконец, удаляя все исходные файлы MKV, для которых были удалены субтитры.

Я ищу, чтобы добавить, когда он запускает mkvmerge -i если есть английские субтитры, сказать ему, чтобы извлечь их в каталог файла MKV перед повторным смешиванием (используя mkvextract).

Answer 1

Определите английские субтитры в видеофайлах MKV с помощью GNU sed:

@echo off&setlocal
set "rootfolder=C:\video\test"
echo Enumerating all MKVs under %rootfolder%
echo.
for /r "%rootfolder%" %%a in (*.mkv) do (
    for /f %%b in ('mkvmerge  --ui-language en -i "%%a" ^| find /c /i "subtitles"') do (
        if "%%b"=="0" (
            echo(%%a has no subtitles
        ) else (
            echo(%%a has subtitles
            set "line="
            for /f "delims=" %%i in ('mkvmerge --ui-language en --identify-verbose "%%a" ^| sed "/subtitles/!d;/language:eng/!d;s/.* \([0-9]*\):.*/\1/"') do (
                echo(english Track ID: %%i
                call set line=%%line%% %%i:"%%~dpna (Sub Track %%i).sub"
            )
            setlocal enabledelayedexpansion
            mkvextract tracks "%%a" --ui-language en !line! ||(echo Demuxing error!&goto:eof)
            endlocal
            mkvmerge -q -o "%%~dpna (No Subs)%%~xa" -S "%%a"
            if errorlevel 1 (
                echo Warnings/errors generated during remuxing, original file not deleted
            ) else (
                del /f "%%a"
                echo Successfully remuxed to "%%~dpna (No Subs)%%~xa", original file deleted
            )
            echo(
        )
    )
)