Как добавить несколько формул в одну ячейку?

Question

Вот формулы, которые мне нужны, но я не могу понять, как их объединить.

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"))
=IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified"))
=IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified"))
=IF(H4=4,IF(J30<=E32,"Pre-Qualified","Unqualified"))
=IF(H4=5,IF(J30<=E33,"Pre-Qualified","Unqualified"))
=IF(H4=6,IF(J30<=E34,"Pre-Qualified","Unqualified"))

Answer 1

Поскольку вы тестируете 1 , 2 , 3 ,…, для вас будет специальный ответ:

=CHOOSE(H4, IF(J30<=E29,"Pre-Qualified","Unqualified"),
            IF(J30<=E30,"Pre-Qualified","Unqualified"),
            IF(J30<=E31,"Pre-Qualified","Unqualified"),
            IF(J30<=E32,"Pre-Qualified","Unqualified"),
            IF(J30<=E33,"Pre-Qualified","Unqualified"),
            IF(J30<=E34,"Pre-Qualified","Unqualified"))

Это имеет тот же эффект, что и составная формула IF - THEN приведенная в других ответах.

Но, поскольку шесть внутренних формул одинаковы, за исключением одного элемента, вы можете значительно упростить это:

=IF(J30<=CHOOSE(H4, E29, E30, E31, E32, E33, E34), "Pre-Qualified", "Unqualified")

Одно отличие: другие ответы будут оцениваться как FALSE если H4 не равно 1 , 2 , 3 , 4 , 5 или 6 , тогда как мои ответы приведут к # #VALUE! ошибка.

Answer 2

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"),
IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified")),
IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified")),
....)

Это будет проверять 2-е, если утверждение, если первое не удается. Так что если Н4!= 1 будет проверять H4 против 2 ...

Answer 3

ЕСЛИ заявления, ЕСЛИ, ТО, ЕЩЕ. Поэтому поместите следующий "IF" в ELSE место последнего оператора IF.

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"),
 IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified"),
 IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified")...)))

Answer 4

Вы можете попробовать выражение if-and следующим образом:

=IF(AND(H1<4,J30<=E29),"Pre-Qualified","Unqualified")

Вы можете ввести несколько переменных в свой оператор и, и если ВСЕ из них истинны, он вернет ИСТИНА, если они не являются истинными, он вернет ложь. Еще одна вещь, которую вы можете попробовать: =IF(OR( работает так же, как AND, за исключением того, что если true, то он вернет true для всего оператора).