Как выбрать множитель на основе определенных ячеек ввода в Excel?

Question

Мне нужна помощь в написании формулы для Excel ниже:

В ячейку A28 будет введено одно из следующих значений: LIN, LOX, LAR, CO2, GH2, GN2 или GO2

В зависимости от того, что введено в ячейку A28, будет иметь значение преобразования, которое необходимо умножить на значение в ячейке D63 и на то, какое произведение нужно поместить в ячейку S63.

Пример:

ЕСЛИ А28 = ЛИН,
ЭТОТ КЛЕТКА D63 ДОЛЖНА БЫТЬ УМНОЖЕНА НА 13,80
И ЭТОТ ПРОДУКТ, РАЗМЕЩЕННЫЙ В CELL S63

LIN = 13.80  
LOX = 12.08  
LAR = 9.671  
CO2 = 1.0  
GH2 =1.0  
GN2 = 1.0  
GO2 = 1.0  

Любая помощь очень ценится!

Answer 1

Вам необходимо иметь отдельную таблицу с каждым из возможных значений (LIN, LOX и т.д.) В одном столбце и связанными коэффициентами преобразования (13.80, 12.08 и т.д.) В следующем столбце. Итак, если эта таблица находится в B1:C7, вы должны ввести следующее в S63:

=D63*VLOOKUP(A28,B1:C7,2,FALSE)

Если вы предпочитаете жестко закодировать значения в формулу, а не создавать отдельную таблицу поиска, вы можете использовать следующую менее элегантную формулу в S63:

=IF(ISBLANK(A28),"",IF(A28="LIN",13.80,IF(A28="LOX",12.08,IF(A28="LAR",9.671,1.0))))

Answer 2

Попробуйте ввести эту формулу в S63

=D63*SUM(
(A28="LIN")*13.8,
(A28="LOX")*12.08,
(A28="LAR")*9.671,
(A28="CO2")*1,
(A28="GH2")*1,
(A28="GN2")*1,
(A28="GO2")*1)

Как он оценивает, если A28 содержит "LOX":

Если вы чувствуете себя немного предприимчивым, вы можете попробовать эти формулы в S63:

=D63*CHOOSE(MATCH(A28,{"LIN";"LOX";"LAR";"CO2";"GH2";"GN2";"GO2"},0),13.8,12.08,9.671,1,1,1,1)

или же

=D63*VLOOKUP(A28,{"LIN",13.8;"LOX",12.08;"LAR",9.671;"CO2",1;"GH2",1;"GN2",1;"GO2",1},2,0)