Количество категорий Outlook для общего почтового ящика

Question

Я пытаюсь подсчитать количество элементов, связанных с категорией в общем почтовом ящике, связанной с моей учетной записью Outlook. Весь код, который я нашел, ссылается только на фактические категории Outlook, и я не уверен, как настроить элемент для просмотра общего почтового ящика, чтобы получить категории для подсчета. Я полагаю, что проблема заключается в коде, выделенном жирным шрифтом ниже, но не могу найти свойство для ссылки на общий почтовый ящик.

Я немного скорректировал этот код для удовлетворения своих потребностей, но он был написан Ширли Чжан:

  Public objDictionary As Object
  Public objExcelApp As Excel.Application
  Public objExcelWorkbook As Excel.Workbook
  Public objExcelWorksheet As Excel.Worksheet

Sub ExportCountofItemsinEachColorCategories()
  Dim objCategories As Object
  Dim objCategory As Object
  Dim objPSTFile As Outlook.Folder
  Dim objFolder As Outlook.Folder
  Dim strExcelFile As String

  'Create a New Excel file
  Set objExcelApp = CreateObject("Excel.Application")
  Set objExcelWorkbook = objExcelApp.Workbooks.Add
  Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
  objExcelWorksheet.Cells(1, 1) = "Color Category"
  objExcelWorksheet.Cells(1, 2) = "Count"

  'Find all the color categories
  Set objDictionary = CreateObject("Scripting.Dictionary")

  'I believe the error is here vvv
  Set objCategories = Outlook.Application.Session.Categories
  For Each objCategory In objCategories
    objDictionary.Add objCategory.Name, 0
  Next

  Set objPSTFile = Outlook.Application.Session.PickFolder

  For Each objFolder In objPSTFile.Folders
    ProcessFolder objFolder
  Next

  'Save the new Excel file
  objExcelWorksheet.Columns("A:B").AutoFit
  strExcelFile = "C:\Users\cdlane\Documents\Color Categories (" & Format(Now, "yyyy-mm-dd_hh-mm-ss") & ").xlsx"
  objExcelWorkbook.Close True, strExcelFile


  MsgBox "Complete!", vbExclamation
End Sub

Answer 1

Sub CategoriesByStore()

    Dim colStores As Stores
    Dim oStore As store
    Dim objCategories As Categories
    Dim objCategory As Category
    Dim i As Long

    Set colStores = Session.Stores

    ' Debug.Print "colStores.count: " & colStores.count

    For i = 1 To colStores.count

        Set oStore = colStores(i)
        Debug.Print "Store " & i & ": " & oStore

        If oStore = "store name from immediate window" Then

            Set objCategories = oStore.Categories
            For Each objCategory In objCategories
                Debug.Print objCategory
            Next

            Exit For

        End If

    Next

End Sub