Как запустить макрос в общем почтовом ящике в Outlook 2013

Question

Я работаю как со своим почтовым ящиком, так и с общим почтовым ящиком. У меня есть макрос для автоматического сохранения вложений в электронных письмах, которые я получаю, но он работает только для моего собственного почтового ящика, а не для общего почтового ящика. Подскажите, пожалуйста, как я могу это сделать?

Это то, что я до сих пор:

Private Declare Function ShellExecute Lib "shell32.dll" Alias _
  "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, _
  ByVal lpFile As String, ByVal lpParameters As String, _
  ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Dim Folder As Outlook.MAPIFolder

  Set Ns = Application.GetNamespace("MAPI")
  Set Folder = Ns.GetDefaultFolder(olFolderInbox)
  Set Items = Folder.Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  If TypeOf Item Is Outlook.MailItem Then
    PrintAttachments Item
  End If
End Sub

Private Sub PrintAttachments(oMail As Outlook.MailItem)
  On Error Resume Next
  Dim colAtts As Outlook.Attachments
  Dim oAtt As Outlook.Attachment
  Dim sFile As String
  Dim sDirectory As String
  Dim sFileType As String

  sDirectory = "I:\Finance_Administration\MMR\Attachments\"

  Set colAtts = oMail.Attachments

  If colAtts.Count Then
    For Each oAtt In colAtts

' This code looks at the last 4 characters in a filename
      sFileType = LCase$(Right$(oAtt.FileName, 4))

      Select Case sFileType

' Add additional file types below
      Case ".xls", ".doc", "docx", ".pdf"

         sFile = sDirectory & oAtt.FileName
         oAtt.SaveAsFile sFile
        'ShellExecute 0, "print", sFile, vbNullString, vbNullString, 0
      End Select
    Next
    End If
End Sub

Answer 1

Чтобы запустить его в папке «Входящие», попробуйте изменить код VBA.

пример

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Dim Folder As Outlook.Folder
  Dim olShareName As Outlook.Recipient


  Set Ns = Application.GetNamespace("MAPI")
  Set olShareName = Ns.CreateRecipient("Om3r@Email.com") '// Owner's email address
  Set Folder = Ns.GetSharedDefaultFolder(olShareName, olFolderInbox) '// Inbox
  Set Items = Folder.Items
End Sub