Excel: как искать в нескольких книгах информацию о ячейках

Question

Добрый день

В настоящее время мы получаем электронные формы, заполненные в формате Excel, от наших клиентов, поэтому у меня есть папка с рабочими книгами.

Каждая книга имеет несколько листов.

Мне нужно поискать в каждой из рабочих книг, чтобы увидеть, заполнены ли диапазоны "J8:Y8 на листе 3" и "G8:AC8 на листе 4", так как они требуют дальнейшего изучения, но только некоторые из них будут заполнены.

также каждая рабочая тетрадь была названа как-то совершенно по-другому.

Я нашел этот код (ниже) в сети, который в принципе делает то, что мне нужно, однако он ищет на каждом листе рабочей книги определенное "значение"

Любая помощь будет принята с благодарностью.

Спасибо

Sub SearchFolders()
Dim fso As Object
Dim fld As Object
Dim strSearch As String
Dim strPath As String
Dim strFile As String
Dim wOut As Worksheet
Dim wbk As Workbook
Dim wks As Worksheet
Dim lRow As Long
Dim rFound As Range
Dim strFirstAddress As String


On Error GoTo ErrHandler
Application.ScreenUpdating = False


'Change as desired
strPath = "c:\MyFolder"
strSearch = "Specific text"

Set wOut = Worksheets.Add
lRow = 1
With wOut
    .Cells(lRow, 1) = "Workbook"
    .Cells(lRow, 2) = "Worksheet"
    .Cells(lRow, 3) = "Cell"
    .Cells(lRow, 4) = "Text in Cell"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set fld = fso.GetFolder(strPath)

    strFile = Dir(strPath & "\*.xls*")
    Do While strFile <> ""
        Set wbk = Workbooks.Open _
          (Filename:=strPath & "\" & strFile, _
          UpdateLinks:=0, _
          ReadOnly:=True, _
          AddToMRU:=False)

        For Each wks In wbk.Worksheets
            Set rFound = wks.UsedRange.Find(strSearch)
            If Not rFound Is Nothing Then
                strFirstAddress = rFound.Address
            End If
            Do
                If rFound Is Nothing Then
                     lRow = lRow + 1
                    .Cells(lRow, 1) = wbk.Name
                    .Cells(lRow, 2) = wks.Name
                    .Cells(lRow, 3) = rFound.Address
                    .Cells(lRow, 4) = rFound.Value
Else
Exit Do

                End If
                Set rFound = wks.Cells.FindNext(After:=rFound)
            Loop While strFirstAddress <> rFound.Address
        Next

            wbk.Close (False)
            strFile = Dir
        Loop
        .Columns("A:D").EntireColumn.AutoFit
    End With
    MsgBox "Done"

ExitHandler:
    Set wOut = Nothing
    Set wks = Nothing
    Set wbk = Nothing
    Set fld = Nothing
    Set fso = Nothing
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox Err.Description, vbExclamation
    Resume ExitHandler
End Sub

Answer 1

Этот код будет работать следующим образом:

1. Откройте новую книгу, где вы хотите.
2. Вставьте код VBA в макрос

3. В ячейку A1 листа 1 укажите путь к папке с книгами, например: C:\users\yourname\folder\

4. В ячейке A2 первый диапазон, например: J8:Y8 а в ячейке B2 - имя листа: Sheet3

5. В ячейке A3 второй диапазон, например: G8:AC8 а в ячейке B3 - имя листа: Sheet4

Преимущество этого кода в том, что если у вас есть больше диапазонов / листов для поиска, вы можете добавить следующие строки.

Это будет выглядеть так:

Теперь запустите макрос и после его выполнения он покажет результаты на Листе 2, показывая имя файла и количество пустых ячеек в каждом диапазоне.

Sub foldersearch()
    Dim wbk As Workbook
    Dim wbk1 As Workbook
    Dim wks As Worksheet
    Dim wks2 As Worksheet
    Dim totaltime As Long
    Dim dtDuration As Date
    Set wbk = ThisWorkbook
    Set wks = wbk.Sheets(1)
    Set wks2 = wbk.Sheets(2)
    starttime = Now()
    wks2.Cells.ClearContents
    dirPath = wks.Cells(1, 1)
    file = Dir(dirPath)
    rowscounter = 0
    Application.ScreenUpdating = False
    While (file <> "")
        If InStr(file, "xls") > 0 Then
            rowscounter = rowscounter + 1
            totalpath = dirPath & file
            Set wbk1 = Workbooks.Open(totalpath, , True)
            rangelist = True
            i = 2
            columnscounter = 2
            While rangelist = True
                thenewrango = wks.Cells(i, 1)
                thenewsheet = wks.Cells(i, 2)
                emptycount = workbooksearch(wbk1, thenewsheet, thenewrango)
                wks2.Cells(rowscounter, 1) = file
                wks2.Cells(rowscounter, columnscounter) = emptycount
                i = i + 1
                columnscounter = columnscounter + 1
                If wks.Cells(i, 1) = "" Then
                    rangelist = False
                End If
            Wend
            wbk1.Close (False)
        End If
        file = Dir
    Wend
    Application.ScreenUpdating = True
    endtime = Now()
    totaltime = DateDiff("s", starttime, endtime)
    a = MsgBox("Finished in" & vbCrLf & totaltime & " seconds", vbOKOnly)
End Sub
Function workbooksearch(wbk1 As Workbook, wksname As Variant, rango As Variant)
    Dim wks1 As Worksheet
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbk1.Sheets(wksname)
    Set wks1 = wbk1.Worksheets(wksname)
    emptycount = 0
    For Each c In wks1.Range(rango)
        If c.Value = "" Then
            emptycount = emptycount + 1
        End If
    Next c
    workbooksearch = emptycount
    Exit Function
HandleError:
    workbooksearch = "N/A"
End Function