Преобразование DWG/DXF в CSV или Excel

Question

Я использую ZWcad и мне нужно получить координаты сотен блоков в листе Excel или.CSV-файл, чтобы я мог импортировать его в оборудование GPS. Я знаю, что есть много инструментов для AutoCAD, я, вероятно, даже могу написать один сам, но что касается ZWcad, у меня, похоже, нет выбора.

Однако ZWcad также сохраняет в DWG и экспортирует во все другие знакомые расширения CAD. Поэтому мне было интересно, если бы я просто сохранил блоки, которые мне нужны для экспорта в определенный файл, мог бы быть инструмент / программа для преобразования этого непосредственно в.CSV.

Answer 1

Ниже приведена простая программа AutoLISP, демонстрирующая, как извлечь координаты точки вставки WCS для выбора ссылок на блоки в CSV-файле с разделителями-запятыми.

(defun c:blk2csv ( / e f i p s )
    (if (and (setq s (ssget '((0 . "INSERT"))))
             (setq f (getfiled "" "" "csv" 1))
             (setq f (open f "w"))
        )
        (progn
            (repeat (setq i (sslength s))
                (setq i (1- i)
                      e (ssname s i)
                      p (trans (cdr (assoc 10 (entget e))) e 0)
                )
                (write-line (apply 'strcat (mapcar 'strcat (mapcar 'rtos p) '("," "," ""))) f)
            )
            (close f)
        )
    )
    (princ)
)