Любой способ стилизовать связанную таблицу Excel в PowerPoint?

Question

У меня есть связанная таблица в моем PPT (PowerPoint 2010), которая является частью рабочей таблицы Excel 2010. Когда я обновляю данные в Excel, таблица автоматически обновляется в PPT, что работает нормально и как и ожидалось.

Теперь проблема заключается в том, как стилизовать эту связанную таблицу, используя встроенные стили PowerPoint 2010. Поэтому, когда вы вставляете обычную таблицу PowerPoint, у вас есть две вкладки на ленте «Инструменты таблицы»: «Дизайн» и «Макет». На вкладке «Дизайн» в разделе «Стили таблиц» можно быстро оформить таблицу, используя набор встроенных стилей таблиц.

Однако, когда у меня есть связанная таблица из Excel, у меня нет этих опций: когда я выбираю таблицу, на вкладке «Инструменты таблицы» на ленте отображается только одна вкладка «Формат». И я не могу использовать ни один из встроенных стилей таблиц PowerPoint. Это делает связанную таблицу несовместимой с точки зрения стиля по сравнению с другими обычными таблицами PowerPoint.

Answer 1

К сожалению, встроенные стили доступны только для таблиц стилей, созданных в PowerPoint, а не связанных или вставленных.

Кладж, который может или не может дать приемлемые для вас результаты, будет состоять в том, чтобы создать пустую таблицу PowerPoint в выбранном вами стиле и затем наложить связанную таблицу Excel. Небольшая перемотка назад и вперед между Excel и PowerPoint может привести к разумному выравниванию, сопоставлению шрифтов и т.д. На рисунке показаны результаты очень быстрого макета, который я сделал.

Answer 2

В общем, связанный контент связан с тем, что PowerPoint понятия не имеет, что это такое; у этого есть изображение содержания (переданный ему приложением, которое произвело содержание ... Excel в данном случае) и ссылка на файл, содержащий фактические данные. Все, что он может сделать для вас, если вы хотите редактировать контент, это активировать его в исходном приложении.

Лучше всего для начала отформатировать таблицу в Excel.

Если вы пытаетесь соответствовать определенному стилю PPT, создайте таблицу в PPT, скопируйте / вставьте ее в Excel. Сначала вы захотите заполнить все ячейки текстом, иначе Excel будет применять форматирование текста по умолчанию к пустым ячейкам. Отрегулируйте ширину столбцов по мере необходимости, добавьте свои реальные данные и сохраните файл. Затем ссылка с него обратно на PPT.

Answer 3

Спасибо за ответы. Но мне кажется, что лучшим решением по-прежнему является стилизация таблицы в PPT и редактирование данных в Excel. Поэтому я написал небольшой фрагмент кода VBA для передачи данных из Excel в PPT, и он отлично работает для меня.

Вот код:

Option Explicit
Option Base 1

Const WB_FINANCIALS As String = "\CPMR Financials.xlsm"
Const WS_SALES As String = "Sales Forecast"

Const SLIDE_SALES_FORECAST As String = "SalesForecast"

Const TABLE_SALES_FORECAST As String = "TableSalesForecast"

Const R_CPMA_COM_SALES As String = "cpma_complete_sales"
Const R_CPMA_LARGE_ATC_SALES As String = "cpma_large_atc_sales"
Const R_CPMA_REGULAR_ATC_SALES As String = "cpma_regular_atc_sales"
Const R_CPMA_REPORTS_SALES As String = "cpma_reports_sales"
Const R_RXR_REPORTS_SALES As String = "rxr_reports_sales"
Const R_TOTAL_SALES As String = "total_sales"


Sub ReadFinancialsBook()
    Dim XLApp As Excel.Application
    Dim FBook As Excel.Workbook
    Dim SalesForecast As Excel.Worksheet

    Set XLApp = Excel.Application
    Set FBook = XLApp.workbooks.Open(FileName:=ActivePresentation.Path + WB_FINANCIALS, ReadOnly:=True)
    Set SalesForecast = FBook.Worksheets(WS_SALES)

    Dim PPT As Presentation
    Dim SalesSlide As Slide

    Set PPT = ActivePresentation
    Set SalesSlide = PPT.Slides(SLIDE_SALES_FORECAST)
    Call ReadSalesForecast(SalesSlide, SalesForecast)

    Set SalesSlide = Nothing
    Set PPT = Nothing

    FBook.Close
    Set SalesForecast = Nothing
    Set FBook = Nothing
    Set XLApp = Nothing
End Sub

Private Sub ReadSalesForecast(S As Slide, WS As Excel.Worksheet)
    Dim T As Table
    Set T = S.Shapes(TABLE_SALES_FORECAST).Table

    Call WriteWSRangeToTable(T, 2, 4, WS, R_CPMA_COM_SALES)
    Call WriteWSRangeToTable(T, 5, 4, WS, R_CPMA_LARGE_ATC_SALES)
    Call WriteWSRangeToTable(T, 8, 4, WS, R_CPMA_REGULAR_ATC_SALES)
    Call WriteWSRangeToTable(T, 11, 4, WS, R_CPMA_REPORTS_SALES)
    Call WriteWSRangeToTable(T, 14, 4, WS, R_RXR_REPORTS_SALES)
    Call WriteWSRangeToTable(T, 17, 4, WS, R_TOTAL_SALES)

    Set T = Nothing
End Sub

Private Sub WriteWSRangeToTable(T As Table, row As Integer, col As Integer, WS As Excel.Worksheet, Name As String)
    Dim i, j, r, c As Integer
    Dim str As String

    r = WS.Range(Name).Rows.Count
    c = WS.Range(Name).Columns.Count

    For i = 1 To r
        For j = 1 To c
            str = CStr(WS.Range(Name).Cells(i, j))
            str = Format(str, "#,##0")
            T.Cell(row + i - 1, col + j - 1).Shape.TextFrame.TextRange.Text = str
        Next j
    Next i
End Sub