Как основать правило outlook на количестве адресов «To:»?

Question

Я хотел бы создать правило Outlook, которое не позволяет мне отправлять электронные письма, содержащие более десяти адресов электронной почты в строке «Кому:». Это вообще возможно? Я использую Outlook 2010 на Windows 7 64-битной.

Мое рассуждение: я рассылаю рассылку на большое количество адресов. Обычно я отправляю это письмо себе с адресами списка рассылки в строке «BCC:». Время от времени я путаюсь и случайно помещаю адреса списка рассылки в строку «Кому:». Это проблема, потому что тогда каждый получатель электронной почты увидит все адреса в списке. Я хочу, чтобы Outlook помешал мне сделать это, или, по крайней мере, предупредил меня, прежде чем отправить его.

Я также приветствую предложения о том, как обойти эту проблему.

Answer 1

Нет встроенного способа сделать это, но вы можете достичь этого с помощью макроса.

Шаги ¹:

1. В Outlook нажмите Alt + F11, чтобы открыть Microsoft Visual Basic.

2. В левой части экрана разверните папку с именем Microsoft Office Outlook и дважды щелкните ThisOutlookSession. ²

3. В окне VbaProject.OTM - TheOutlookSession, выберите Application слева и ItemSend в правом раскрывающемся меню. ²

4. Замените код, который появился в теле окна, следующим текстом:

   Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
       Dim Recipients As Integer
       Dim Start As Integer
       Dim Last As Integer
       Recipients = 1
       Do
           Start = Last + 1
           Last = InStr(Start, Item.To, ";")
           If Last = 0 Then Exit Do
           Recipients = Recipients + 1
       Loop
       If (Recipients > 10) Then
           Cancel = (MsgBox(Str(Recipients) & " recipients in To field.", vbOKCancel) = vbCancel)
       End If
   End Sub
   

5. Нажмите Ctrl + S, чтобы сохранить.

6. Нажмите Alt + Q, чтобы вернуться в Outlook.

Этот макрос будет отображать предупреждение, если в поле « Кому» содержится более 10 получателей (в зависимости от количества точек с запятой, используемых для разделения получателей). Вы можете нажать OK чтобы отклонить предупреждение, или Cancel чтобы отменить. ³

---

¹ Я использую Outlook 2007 (на испанском языке). Я надеюсь, что Outlook 2010 похож.

²

³

Answer 2

К сожалению, это невозможно с Outlook. Хотя вы можете использовать сторонние решения для его ограничения (например, Thunderbird), вы теряете функциональность самого Outlook. Хотя на самом деле это отличный вопрос, и мне бы хотелось, чтобы Microsoft обеспечила немного лучший контроль над тем, что вы можете и не можете отправлять!

Answer 3

Я взял ответ Судо и сделал так, чтобы он считал получателей в ЦК и БЦК, на всякий случай, если кто-то захочет:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim Recipients As Integer
    Dim Start As Integer
    Dim Last As Integer
    Dim RecipientFields As String
    Recipients = 1

    RecipientFields = Item.To

    If (Item.CC <> "") Then
        RecipientFields = RecipientFields + ";" + Item.CC
    End If

    If (Item.BCC <> "") Then
        RecipientFields = RecipientFields + ";" + Item.BCC
    End If

    Do
        Start = Last + 1
        Last = InStr(Start, RecipientFields, ";")
        If Last = 0 Then Exit Do
        Recipients = Recipients + 1
    Loop

    If (Recipients > 6) Then
        Cancel = (MsgBox("You have " & Str(Recipients) & " recipients in To/CC/BCC fields.  Click OK to send.", vbOKCancel) = vbCancel)
    End If
End Sub