Excel - создать текстовый файл с именем ячейки, содержащей другие данные ячейки

Question

Я ищу, чтобы создать .txt file для каждого значения в column A содержащий соответствующие значения в columns B and C

Answer 1

Чем больше я смотрел на это, тем больше находил полезный маленький макрос. Чтобы он не обрабатывал пустые строки (и не блокировал мой Excel), я переписал код, создавая файл только при наличии доступных данных. Кроме того, использование print вместо write создает текст без кавычек. Вот что я использовал для достижения того же.

Sub CreateFile()
Do While Not IsEmpty(ActiveCell.Offset(0, 1))
    MyFile = ActiveCell.Value & ".txt"
    'set and open file for output
    fnum = FreeFile()
    Open MyFile For Output As fnum
    'use Print when you want the string without quotation marks
    Print #fnum, ActiveCell.Offset(0, 1) & " " & ActiveCell.Offset(0, 2)
Close #fnum
ActiveCell.Offset(1, 0).Select
Loop
End Sub

Не стесняйтесь использовать и изменять по своему желанию. Спасибо за отличную идею.

Answer 2

Этот макрос будет принимать каждое значение в column A , создавать .txt document с именем значения и вставлять соответствующую информацию из columns B and C

Sub CreateTxt()
'
For Each ce In Range("A1:A" & Cells(Rows.Count, 1).End(xlDown).Row)
    Open ce & ".txt" For Output As #1
    Write #1, ce.Offset(0, 1) & " " & ce.Offset(0, 2)
    Close #1
Next ce
End Sub

---

Четыре года спустя я решил вернуться к моему первому вопросу SU - моим самым началом VBA. Это лучше, но перезапишет любой файл, который уже существует

Option Explicit

Sub CreateFileEachLine()

    Dim myPathTo As String
    myPathTo = "C:\Users\path\to\"
    Dim myFileSystemObject As Object
    Set myFileSystemObject = CreateObject("Scripting.FileSystemObject")
    Dim fileOut As Object
    Dim myFileName As String

    Dim lastRow As Long
    lastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Dim i As Long

        For i = 1 To lastRow
            If Not IsEmpty(Cells(i, 1)) Then
                myFileName = myPathTo & Cells(i, 1) & ".txt"
                Set fileOut = myFileSystemObject.CreateTextFile(myFileName)
                fileOut.write Cells(i, 2) & "    " & Cells(i, 3)
                fileOut.Close
            End If
        Next

    Set myFileSystemObject = Nothing
    Set fileOut = Nothing
End Sub