Фильтрация писем в Outlook, адресованных X людям

Question

Я хотел бы иметь возможность фильтровать электронные письма, которые отправляются более чем, например, 15 людям? Возможно ли что-то подобное? В Outlook 2016? Или что-то подобное можно создать с помощью макроса / visual basic с опциями разработчика?

Вопрос не является дубликатом, поскольку я прошу фильтр, а не предупреждение, когда случайно отправил электронное письмо +15 людям.

Answer 1

Public WithEvents myOlApp As Outlook.Application

Sub Application_Startup()
    Set myOlApp = Outlook.Application
End Sub

Private Sub myOlApp_NewMailEx(ByVal EntryIDCollection As String)
    Dim item As MailItem
    Dim olItem As Outlook.MailItem
    Dim arr() As String
    Dim i As Integer
    Dim objFolderInbox As Outlook.MAPIFolder
    Dim objFolderDL As Outlook.MAPIFolder

    Set objNS = myOlApp.GetNamespace("MAPI")
    Set objFolderInbox = objNS.GetDefaultFolder(olFolderInbox)
    Set objFolderDL = objFolderInbox.Folders("E-mail DL")

    On Error GoTo ErrorHandler

    ' Split collection
    arr = Split(EntryIDCollection, ",")

    ' For each new e-mail / event / etc
    For i = 0 To UBound(arr)
        ' Set item
        Set item = objNS.GetItemFromID(arr(i))

        ' Check if e-mail
        If item.Class = olMail Then
            Set olItem = item
            Set Recips = olItem.Recipients

            ' Check if number of recipients > 15
            If Recips.Count > 15 Then
                ' Move to different folder
                olItem.Move objFolderDL
            End If
        End If
    Next

ProgramExit:
    Exit Sub

ErrorHandler:
    MsgBox Err.Number & " - " & Err.Description
    Resume ProgramExit
End Sub

Answer 2

Вы должны быть в состоянии достичь этого с помощью фильтров в outlook под View -> View settings> Filters. Если нет, вы можете сделать это с помощью построителя запросов, который можно включить через regedit.

Добавьте новый ключ по следующему пути HKEY_CURRENT_USER\Software\Microsoft\Office\16.0\Outlook

Назовите это QueryBuilder. Теперь вы сможете найти построитель запросов в настройках просмотра.