Напоминание для встреч Outlook

Question

У меня не может быть приложение Outlook Android из-за корпоративной политики (доступ к электронной почте только на моем рабочем ПК). Есть ли в Outlook 2010 функция отправки напоминаний о собраниях по не корпоративной (внешней) электронной почте?

Answer 1

Я протестировал следующий скрипт, и он работает, как вы и просили.

• Откройте Outlook и нажмите Alt+F11.
• Перейдите в ThisOutlookSession и вставьте следующий скрипт

Private Sub Application_Reminder(ByVal Item As Object)
  Dim objMsg As MailItem
  ' create new outgoing message
  Set objMsg = Application.CreateItem(olMailItem)
   ' your reminder notification address
  objMsg.To = "youraddress@wherever.com"
  objMsg.Subject = "Reminder: " & Item.Subject
  ' must handle all 4 types of items that can generate reminders
  Select Case Item.Class
     Case olAppointment '26
        objMsg.Body = _
          "Start: " & Item.Start & vbCrLf & _
          "End: " & Item.End & vbCrLf & _
          "Location: " & Item.Location & vbCrLf & _
          "Details: " & vbCrLf & Item.Body
     Case olContact '40
        objMsg.Body = _
          "Contact: " & Item.FullName & vbCrLf & _
          "Phone: " & Item.BusinessTelephoneNumber & vbCrLf & _
          "Contact Details: " & vbCrLf & Item.Body
      Case olMail '43
        objMsg.Body = _
          "Due: " & Item.FlagDueBy & vbCrLf & _
          "Details: " & vbCrLf & Item.Body
      Case olTask '48
        objMsg.Body = _
          "Start: " & Item.StartDate & vbCrLf & _
          "End: " & Item.DueDate & vbCrLf & _
          "Details: " & vbCrLf & Item.Body
  End Select
  ' send the message 
  objMsg.Send
  Set objMsg = Nothing
End Sub

• Измените youraddress@wherever.com с вашим внешним адресом электронной почты.
• Сохранить и выйти.

---

Источник