AutoHotkey - горячая клавиша 1 сделать что-то, последовательность клавиш 11 сделать другую вещь

Question

Я довольно новичок в AHK, я хотел бы, чтобы Autohotkey всякий раз, когда я нажимаю горячую клавишу "1" в MS Word типа HELLOW, но в то же время в том же приложении (MS Word) я хочу комбинацию клавиш "11" (клавиша 1 нажата два раза очень быстро) набрать BYE, это возможно? будет ли AHK набирать "1HELLOW", когда я набираю "1", будет ли он печатать "11BYE", когда я набираю "11"? Можно ли сделать тот же сценарий, но вместо этого с F1? Я имею в виду F1, и последовательность клавиш F1F1 (F1 нажимается дважды очень быстро)

Пока я пробовал это

~1::
;400 is the maximum allowed delay (in milliseconds) between presses.
if (A_PriorHotKey = "~1" AND A_TimeSincePriorHotkey < 400)
{
   Msgbox,Double press detected.
}
else if (A_PriorHotKey = "~1" AND A_TimeSincePriorHotkey > 400)
{
    Msgbox,Single press detected.
}

Sleep 0
KeyWait 1
return

Но он работает только при первом нажатии последовательности клавиш 11 (быстро нажимается 1), тогда он всегда будет распознавать только клавишу 1, почему ???

~1::
if (A_PriorHotkey <> "~1" or A_TimeSincePriorHotkey > 400)
{
    ; Too much time between presses, so this isn't a double-press.
    KeyWait, 1
    return
}
MsgBox You double-pressed the 1 key.
return

это не поможет получить две горячие клавиши (1 и 11).

Спасибо, Дополнительно.

Answer 1

Лучше всего работает с использованием SetTimer:

    ; The following hotkeys work only if MS-WORD is the active window:
#If WinActive("ahk_exe WINWORD.EXE")    ; (1)

    1::
    if 1_presses > 0
    {
        1_presses += 1
        SetTimer Key1, 300
        return
    }
    1_presses = 1
    SetTimer Key1, 300
    return

    Key1:
    SetTimer Key1, off
    if 1_presses = 2
      SendInput, BYE
    else
      SendInput, HELLOW
    1_presses = 0
    return

    F2:: MsgBox, You pressed F2 in MS-Word


    ; The following hotkeys work only if NOTEPAD is the active window:
#If WinActive("ahk_exe NOTEPAD.EXE") 

    1:: Send 2

    F2:: MsgBox, You pressed F2 in NOTEPAD


#If ; turn off context sensitivity (= end of context-sensitive hotkeys)


; The following hotkeys work only if MS-WORD or NOTEPAD is NOT the active window (because they are already defined in those programs):

1:: Send 3

F2:: MsgBox, You pressed F2 while  MS-WORD or NOTEPAD is NOT the active window


; The following hotkeys work in all windows (incl. MS-WORD and NOTEPAD because they are NOT defined in those programs)

F3:: MsgBox, You pressed F3

Esc:: ExitApp

https://autohotkey.com/docs/commands/SetTimer.htm#Examples (пример № 3)

(1) Как и директивы #IfWin , #If создает контекстно-зависимые горячие клавиши и горячие строки и является позиционным: он воздействует на все горячие клавиши и горячие строки физически под ним в скрипте.