AcroRd32.exe Maxes Out Core

Question

Мое использование процессора достигло 100%. Process Explorer показывает два экземпляра AcroRd32.exe. Каждый из них максимально 1 ядро. Но окно Adobe/Acrobat Reader не отображается. Я закрыл окна раньше. Как мне решить это?

Answer 1

Acrord32.exe обычно связан с Adobe Acrobat Reader.

Если вы не запустили его самостоятельно (открыв документ PDF), возможно, он работает из веб-браузера, такого как Internet Explorer, Firefox или Chrome. У вас есть браузер с открытыми документами PDF?

В противном случае возможно, что Adobe Reader поврежден, и в этом случае вы можете попытаться удалить текущую версию и повторно загрузить ее из Adobe.

В качестве последнего средства потенциально возможно, что это вирус, маскирующийся под Adobe Reader, попробуйте следовать советам в этом вопросе относительно сканирования на вирусы и общей очистки компьютера.

Answer 2

Это может быть вирусная программа с именем «acrord32.exe», знакомое название для запуска без сомнений.

В Process Explorer щелкните по нему правой кнопкой мыши, затем просмотрите свойства и посмотрите путь: настоящий Acrobat Reader?

Answer 3

Позвольте мне рассказать о своей работе в этом направлении.

Еще один способ закрытия процесса загрузки системы. Тогда нет необходимости вносить какие-либо изменения в реестр, параметры или настройки Acrobat Reader. Пакетный сценарий, подготовленный по умолчанию, закрывает процесс Acrord32.exe и с этой целью был разработан, но сценарий можно использовать для закрытия, так как любой другой процесс слишком обременителен для системы, которая была приостановлена, когда сценарий вызывает соответствующий параметр. Если этот параметр содержит длинное имя с пробелом, его необходимо заключить в кавычки. Внутри скрипта, к началу можно определить, например, несколько параметров. Время приостановки, время повторной проверки или место создания отчета (LOG). Скрипт закрывает все процессы, отвечающие критериям любого пользователя, конечно, не той системы, которая не может быть закрыта. Может быть полезна на сервере работа многих пользователей. Скрипт оптимизирован для того, чтобы минимизировать нагрузку на себя процессора.

Скопируйте следующий текст и сохраните как файл Batch (расширение.BAT) с любым именем файла, который вы хотите.

@echo off
REM Automatic closing Acrobat Reader or other process parameter specified in the call, which too much high the CPU
REM Preparing:  Artur Zgadzaj
REM ---------------------------------------------------------------------------------------------

SET REPEAT_TIME_VERIFICATION_[seconds]=7
SET IDLE_TIME_[seconds]=5

SET LOG_FOLDER=C:\UTIL\LOG

REM    # # # #      CHECKING OR IS STARTED AS ADMINISTRATOR     # # # # #

FSUTIL | findstr /I "volume" > nul&if not errorlevel 1  goto Administrator_OK

cls
echo ************************************
echo ***    RUN  AS  ADMINISTRATOR    ***
echo ************************************
echo.
echo.
echo Call up just as the Administrator. Abbreviation can be done to the script and set:
echo.
echo      Shortcut ^> Advanced ^> Run as Administrator
echo.
echo.
echo Alternatively, a single run "Run as Administrator"
echo or in the Schedule tasks with highest privileges
pause > nul
goto:eof
:Administrator_OK

SET WD=day
if "%~1"==""  (SET Close_Process=AcroRd32.exe)  else  (SET "Close_Process=%~1")
MD %LOG_FOLDER% 2>NUL
Setlocal EnableDelayedExpansion

:again
cls
echo Automatic closing %Close_Process%, which are charged to the processor too ...&echo.&echo.

FOR /F "tokens=2,7,8 delims=,"  %%A IN ('%SystemRoot%\System32\tasklist.exe /v /FO CSV^|find /I ^"%Close_Process%^"') DO (

  SET PROC=%%C
  SET PROC=!PROC:"=!

  FOR /F "tokens=2,3 delims=:"  %%s IN ("!PROC!") DO (SET PR=%%t
      if "!PR:~0,1!"=="0"  (SET /A PROC_TIME=%%s*60+!PR:~1,1!)  else  (SET /A PROC_TIME=%%s*60+!PR:~0,2!))

  if !PROC_TIME! GTR %IDLE_TIME_[seconds]%   (
      SET PID=%%A
      SET PID=!PID:"=!

      %SystemRoot%\system32\taskkill.exe /PID !PID! /F

      SET B=%%B
      SET B=!B:%USERDOMAIN%\=!
      SET B=!B:%COMPUTERNAME%\=!
      SET Process_User=!B:"=!

      if not "!DATE_WD!"=="%DATE%" ((FOR /F "tokens=1" %%W IN ('POWERSHELL GET-DATE -format dddd') DO SET WD=%%W)&&SET DATE_WD=%DATE%)
      echo %TIME:~0,8%    ^(Hanging:  !PROC:~-5!^)         !Process_User! >>"%LOG_FOLDER%\%DATE:-=.%  ^(!WD:~0,3!^)  Close_%Close_Process%.TXT"
      )
  )

TIMEOUT /T %REPEAT_TIME_VERIFICATION_[seconds]% > nul
goto again