Обработка простых текстовых данных

Question

У меня есть этот простой текстовый файл, который мне нужно автоматически проверить, а результаты записаны в другом текстовом файле. Обратите внимание, что я буду использовать простой текст и CSV взаимозаменяемо, поскольку CSV - это простой текст с общим разделителем между данными (запятыми, табуляциями и т.д.).

Примеры данных

ABD-01A
ABD-01B
ABD-01C
AL-25A
AL-25B

Обработка первая - распознать первые два раздела данных (text - number), чтобы повторить, и сосчитать их в выходном CSV:

ABD-01,1
ABD-01,2
ABD-01,3
AL-25,1
AL-25,2

Процесс второй - Первая часть собранных выше данных имеет своего рода первичный ключ, назначенный им в другом файле. Я хотел бы получить первичные ключи, упомянутые во вновь созданных файлах:

#primary key file
1,ABD-01
2,ABD-02
3,AL-02
20,AL-25

#newly generated file
1,ABD-01,1
1,ABD-01,2
1,ABD-01,3
20,AL-25,1
20,AL-25,2

В общем, я спрашиваю ее, есть ли какое-нибудь программное обеспечение, которое может помочь мне с этим в операционных системах на базе Windows или Linux. Bash может помочь мне с более простой обработкой, но я не думаю, что он справится с этим. Пожалуйста, порекомендуйте.

Answer 1

Процесс 1

perl count.pl datafile …

где count.pl что-то вроде

#!perl
use strict;
use warnings;

my %headwordcount;

while (<>) {
  if (/^([A-Z]+-\d+)/) { $headwordcount{$1}++; }
  # else { warn "Bad data: $_"; } # uncomment line for data warnings
}

END {
  foreach (sort keys %headwordcount) {
     print "$_,$headwordcount{$_}\n";
  }
}

Не проверено, будьте бдительны.

Процесс 2

Добавить что-то вроде

   my %key;

   BEGIN {
     my $keyfilename = 'primary.key';
     open my $fh, '<', $keyfilename or die "Can't read '$keyfilename' - $!\n";
     while (<$fh>) {
        chomp;
        my ($key,$headword) = split(/,/, $_, 2);
        $key{$headword} = $key;        
     }
     close $fh;
   }

и измените строку печати в END {} на

   print "$key{$_},$_,$headwordcount{$_}\n";

Опять не проверено.

Вы будете генерировать предупреждения, если файл данных содержит заголовки, которых нет в файле ключей. Вы можете проверить, что $key{$_} не определен, и если это так, печатать без ключа.

Answer 2

Я бы сделал это на Python, используя регулярные выражения. Просто введите python в вашей оболочке, чтобы увидеть, установлен ли он.

В противном случае вы можете использовать Perl. Просто введите perl в вашей оболочке, чтобы увидеть, установлен ли он. Имеет встроенную поддержку регулярных выражений.

Answer 3

1. Выберите предпочитаемый язык - Perl хорошо работает с текстом; С Python, PHP и Ruby все в порядке, если немного медленнее.
2. Сначала прочтите файл ключа:
   • разделить каждый key,data строку данных на key и data ,
   • затем сохраните оба в dict/hash/array: keys[data] = key
   • также counts[data] = 0 если язык требует инициализации
3. Прочитать все файлы данных:
   1. используйте регулярное выражение, чтобы найти данные «ТЕКСТ-НОМЕР» в начале каждой строки,
   2. приращение counts[data] на единицу,
   3. и сразу же выведите keys[data] , строку и counts[data] .

Я написал пример скрипта на Perl и Python, поэтому ваш выбор:

process.pl

#!/usr/bin/env perl
use strict;

sub usage {
    print "Usage: $0 <key_file> <data_file...>\n";
    return 2;
}

my $keys_file = shift(@ARGV) // exit(usage);
my @data_files = @ARGV;

my %keys;   # $data => $primarykey
my %counts; # $data => $count

# Read keys

open(my $fh, "<", $keys_file) or die "$!";
while (my $line = <$fh>) {
    chomp($line);
    my ($key, $datum) = split(/,/, $line, 2);
    if (!defined $datum) {
        warn "$keys_file: line $. not in KEY,DATA format: '$line'\n";
        next;
    }

    $keys{$datum} = $key;
    $counts{$datum} = 0;
}
close($fh);

# Read and output data

my $ex = qr/^(\w+-\d+)\w*/;
for my $data_file (@data_files) {
    open(my $fh, "<", $data_file) or die "$!";
    while (my $line = <$fh>) {
        chomp($line);
        if ($line =~ /$ex/) {
            my $datum = $1;
            if (!defined $keys{$datum}) {
                warn "no primary key found for data '$datum'\n";
                next;
            }

            # Increment count, then print processed line immediately
            $counts{$datum}++;
            print "$keys{$datum},$&,$counts{$datum}\n";
        }
        else {
            warn "$data_file: line $. does not begin with TEXT-NUMBER: '$_'\n";
        }
    }
    close($fh);
}

process.py

#!/usr/bin/env python
from __future__ import print_function
import sys
import re

def usage():
    print("Usage: %s <key_file> <data_file...>" % sys.argv[0])
    return 2

try:
    keys_file = sys.argv[1]
    data_files = sys.argv[2:]
except IndexError:
    sys.exit(usage())
except ValueError:
    sys.exit(usage())

keys = {}
counts = {}

# Read keys

for line in open(keys_file, "r"):
    try:
        key, datum = line.strip().split(",", 1)
    except ValueError:
        print("%s: line not in KEY,DATA format: %r" \
            % (keys_file, line.strip()), file=sys.stderr)
        continue

    keys[datum] = key
    counts[datum] = 0

# Read and output data

ex = re.compile(r'^(\w+-\d+)\w*')
for data_file in data_files:
    for line in open(data_file, "r"):
        line = line.strip()
        m = re.match(ex, line)
        if m:
            datum = m.group(1)
            if datum not in keys:
                print("no primary key found for data %r" % datum,
                    file=sys.stderr)
                continue

            # Increment count, then print processed line immediately
            counts[datum] += 1
            print("%s,%s,%d" % (keys[datum], m.group(0), counts[datum]))
        else:
            print("%s: line does not begin with TEXT-NUMBER: %r" \
                % (data_file, line.strip()), file=sys.stderr)