Удалить контакт из группы контактов в outlook

Question

Недавно коллега ушел из нашей компании, и мне нужно удалить ее из
все группы контактов в моем Outlook.
Любое предложение будет оценено!
Есть ли простой способ сделать это?

Answer 1

Для удаления одного контакта из всех групп требуется макрос VBA.

Такой макрос подробно описан в статье Как быстро удалить определенный контакт из всех групп контактов через Outlook VBA.

В статье подробно рассказывается, как такой макрос устанавливается на вкладке «Разработчик» / Visual Basic, и позже его можно запустить с помощью значка «Выполнить» на панели инструментов.

Если эта статья позже исчезнет, макрос VBA будет подробно описан здесь:

Sub RemoveSpecificContactfromAllGroups()
    Dim strSpecificContact As String
    Dim objTempMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objContactsFolder As Outlook.Folder
    Dim objItem As Object
    Dim objContactGroup As Outlook.DistListItem
    Dim objContact As Outlook.ContactItem
    Dim nprompt As Integer

    strSpecificContact = InputBox("Input the fullname or email address of the specific contact to be removed from all contact groups:")
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
    Set objRecipient = objTempMail.Recipients.Add(strSpecificContact)
    objRecipient.Resolve

    If objRecipient.Resolved = True Then
       Set objContactsFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
       For Each objItem In objContactsFolder.Items
           If TypeOf objItem Is DistListItem Then
              Set objContactGroup = objItem
              With objContactGroup
                   .RemoveMember objRecipient
                   .Body = "Contact Removed: " & strSpecificContact & vbTab & "(" & Now & ")" & .Body
                   .Save
              End With
           End If
       Next
       nprompt = MsgBox("Removing Completes!", vbExclamation, "Remove Contact from Group")
    Else
       nprompt = MsgBox("This contact cannot be resolved!", vbExclamation, "Resolving Error")
    End If
End Sub