5

Я обновил коробку Win7 с SP1 и обновил браузер до IE11. Я хотел бы удалить любые файлы, которые не требуются для операций (например, установить файлы и т.д.), Чтобы избежать ненужного архивирования их с помощью Clonezilla. Есть хороший сценарий, список или процедура, которая поддерживает эту цель? Спасибо

|источник

1 ответ1

7

Сценарий очистки Windows 7 и процессы

Ниже приведен пакетный скрипт, который я использовал в прошлом для очистки компьютеров с Windows 7 и Windows Vista перед созданием образа, поэтому сделайте это, если хотите.

Посмотрите sysprep и подумайте об его использовании и запустите его, и как только компьютер выключится, вы захотите сделать образ с CloneZilla, прежде чем он загрузится обратно в Windows.

Пакетный скрипт

Я обязательно посмотрю сценарий и закомментирую все, что вы не хотите включать в процесс, и предварительно протестирую его на тестовом компьютере, а также для того, чтобы быть в безопасности, ничего не требуется, вычищается или удаляется для ваших нужд.

Это пакетный скрипт, поэтому просто сохраните его в текстовом документе с расширением .cmd или .bat и обязательно щелкните правой кнопкой мыши, чтобы запустить его с правами администратора.

Я знаю, что некоторые из этих процессов также являются избыточными, но я просто не получил возможности очистить эти дублирующие процессы, но это не помешает запустить процесс удаления или очистки одной и той же папки и т.д. Дважды в любом случае.

@ECHO on

TASKKILL /F /IM explorer.exe

ECHO *****""Stopping Windows Services""****
NET STOP /Y "Themes"
NET STOP /Y "Windows Update"
NET STOP /Y "Fax"
NET STOP /Y "Print Spooler"
NET STOP /Y "Remote Registry"
NET STOP /Y "Background Intelligent Transfer Service"
NET STOP /Y "Office Source Engine"
NET STOP /Y "Offline Files"
NET STOP /Y "Secondary Logon"
NET STOP /Y "Java Quick Starter"
NET STOP /Y "IIS Admin"
NET STOP /Y "smart card"
NET STOP /Y "Tablet PC Input Service"
NET STOP /Y "Telephony"
NET STOP /Y "Windows Media Player Network Sharing Service"
NET STOP /Y "Windows Mobile 2003-based device connectivity"
NET STOP /Y "Windows Mobile-based device connectivity"
NET STOP /Y "Cisco Systems, Inc. VPN Service"
NET STOP /Y "Adobe LM Service"
NET STOP /Y "Adobe Flash Player Update Service"
NET STOP /Y "Bluetooth Support Service"

SC CONFIG "Adobe Flash Player Update Service" START= manual
SC CONFIG "Adobe LM Service" START= manual
SC CONFIG "Fax" START= manual
SC CONFIG "Offline Files" START= manual
SC CONFIG "Java Quick Starter" START= manual
SC CONFIG "Tablet PC Input Service" START= manual
SC CONFIG "Windows Media Player Network Sharing Service" START= manual
SC CONFIG "Windows Mobile 2003-based device connectivity" START= manual
SC CONFIG "Windows Mobile-based device connectivity"" START= manual

::Setting Source Directories as Variables
SET SRC1=C:\Users
SET SRC2=AppData\Local\Temp
SET SRC3=AppData\Local\Microsoft\Windows\Temporary Internet Files
SET SRC4=AppData\Local\Microsoft\Windows\History
SET SRC5=AppData\Microsoft\Windows\Cookies
SET SRC6=AppData\Local\Microsoft\Windows\WER
SET SRC7=AppData\Local\Microsoft\Windows\Explorer
SET SRC8=AppData\Local

ECHO ****Deleting User\AppData\Local\Temp Sub-Directories****
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC2%\*.*") DO DEL /F /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC2%\") DO RMDIR /S /Q "%%Y"

ECHO ***Deleting User\AppData\Local\MS\Windows\Temporary Internet Files***
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC3%\*.*") DO DEL /F /S /Q "%%Y"

ECHO ***Deleting User\AppDate\Local\MS\Windiws\History Sub-Directories***
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC4%\*.*") DO DEL /F /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC4%\") DO RMDIR /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC3%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\Cookies Sub-Directories**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC5%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\WER\ReportArchive & Report Queue**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC6%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\Explorer**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC7%\*.*") DO DEL /F /S /Q "%%Y"


ECHO ****""Deleting Non-User Temp files and directories""****
RMDIR /S /Q C:\WINDOWS\SoftwareDistribution
DEL /F /S /Q %TEMP%\*.*
DEL /F /S /Q %systemroot%\temp\*.*
DEL /F /S /Q C:\ProgramData\TEMP\*.*
DEL /F /S /Q C:\Windows\Temp\*.*
DEL /F /S /Q %windir%\Temp\*.*
FOR /D %%X IN ("%windir%\temp\*") DO RMDIR /S /Q "%%X"

ECHO **Recreate all %userprofile%\Appdata\Local\Temp\Low directory**
FOR /D %%X IN (%SRC1%\*) DO FOR /D %%Y IN (%%X\%SRC8%) DO MD %%Y\Temp\Low

ECHO **Set security level back up on all %userprofile%\Appdata\Local\Temp\Low directory**          
FOR /D %%X IN (%SRC1%\*) DO FOR /D %%Y IN (%%X\%SRC8%) DO ICACLS %%Y\Temp\Low /setintegritylevel (OI)(CI)low

ECHO ** Remove all print jobs that are pendning**
DEL /Q /F "%systemroot%\system32\spool\printers\*.shd"
DEL /Q /F "%systemroot%\system32\spool\printers\*.spl"

::Empty all recycle bins
RD /S /Q C:\recycler
RD /S /Q C:\$RECYCLE.BIN

ECHO *** Turn off Windows hibernation power save setting ***
POWERCFG HIBERNATE OFF

ECHO *** Resize VSS (shadow storage) ***
VSSADMIN RESIZE SHADOWSTORAGE /FOR=C: /ON=C: /MAXSIZE=1GB

ECHO *** Set disk cleanup parameters to clean and then clean after being set ***
CLEANMGR /D c: /SAGESET:100
PAUSE
CLEANMGR /SAGERUN:100

ECHO *** Flush DNS ***
IPCONFIG /FLUSHDNS

ECHO *** Reset TCP/IP ***
NETSH INT IP RESET

ECHO *** Reset Winsock ***
NETSH WINSOCK RESET CATALOG

explorer.exe

GOTO EOF

Команды Dism

Примечание. Если вы получите ошибку 1260, то это, скорее всего, означает, что у вас отключено восстановление системы в групповой политике или что-то в этом роде.Поэтому просто включите Восстановление системы, а затем снова запустите эти команды из командной строки с повышенными привилегиями администратора. Кроме того, вам может потребоваться запустить CD /D "C:\Windows\System32" перед выполнением каждой из следующих команд.

Следующая команда удалит все предыдущие версии компонентов без 30-дневного льготного периода для запланированной задачи:

DISM.exe /online /Cleanup-Image /StartComponentCleanup

Следующая команда удалит файлы, необходимые для удаления пакетов обновления. Вы не сможете удалить все установленные на данный момент пакеты обновления после выполнения этой команды:

DISM.exe /online /Cleanup-Image /SPSuperseded

Следующая команда удалит все старые версии каждого компонента. Вы не сможете удалить какие-либо установленные на данный момент пакеты обновления или обновления после завершения этого:

DISM.exe /online /Cleanup-Image /StartComponentCleanup /ResetBase\

источник

Дополнительные ресурсы

|источник

Всё ещё ищете ответ? Посмотрите другие вопросы с метками .