Excel VBA Получить данные из закрытой рабочей книги, используя именованный диапазон

Question

Я использую код, найденный здесь (скопированный ниже), чтобы извлечь данные из закрытых рабочих книг.

Чего я хотел бы добиться, так это использовать именованный диапазон в целевом источнике, а не жестко закодированный адрес. Итак, в строке 22, где он определяет Address = Cells(Row, Column).Address Я хочу иметь возможность просто передать ему namedRange (который существует в цели) вместо этого ... но это, кажется, делает функцию getData() больше не работающей.

Option Explicit 

 'you can extract data from a closed file by using an
 'XLM macro. Credit for this technique goes to John
 'Walkenback > http://j-walk.com/ss/excel/tips/tip82.htm

Sub GetDataDemo() 

  Dim FilePath$, Row&, Column&, Address$ 

   'change constants & FilePath below to suit
   '***************************************
  Const FileName$ = "Book1.xls" 
  Const SheetName$ = "Sheet1" 
  Const NumRows& = 10 
  Const NumColumns& = 10 
  FilePath = ActiveWorkbook.Path & "\" 
   '***************************************

  DoEvents 
  Application.ScreenUpdating = False 
  If Dir(FilePath & FileName) = Empty Then 
      MsgBox "The file " & FileName & " was not found", , "File Doesn't Exist" 
      Exit Sub 
  End If 
  For Row = 1 To NumRows 
      For Column = 1 To NumColumns 
          Address = Cells(Row, Column).Address 
          Cells(Row, Column) = GetData(FilePath, FileName, SheetName, Address) 
          Columns.AutoFit 
      Next Column 
  Next Row 
  ActiveWindow.DisplayZeros = False 
End Sub 


Private Function GetData(Path, File, Sheet, Address) 
  Dim Data$ 
  Data = "'" & Path & "[" & File & "]" & Sheet & "'!" & _ 
  Range(Address).Range("A1").Address(, , xlR1C1) 
  GetData = ExecuteExcel4Macro(Data) 
End Function 

Answer 1

Итак, я нашел ответ .... кажется, я не достаточно хорошо Google, прежде чем отправлять, поэтому извинения.

В приведенном выше коде в Private Function GetData() замените:

Data = "'" & Path & "[" & File & "]" & Sheet & "'!" & _ 
       Range(Address).Range("A1").Address(, , xlR1C1)

с:

Data = "'" & Path & File & "'!" & Address

где Address можно установить с помощью строкового значения namedRange ... и все хорошо.