Как полностью избавиться от OneDrive?

Question

Во-первых, я попробовал https://superuser.com/a/947575/247842, который использует gpedit.msc Во-вторых, я попробовал https://superuser.com/a/949571/247842, который использует SysWOW64\OneDriveSetup .exe для удаления и удаления некоторых оставшихся ключей реестра.

Я перезагрузился.

И все же каждый раз, когда я открываю проводник, у меня появляется этот большой рекламный баннер, который заставляет меня ненавидеть даже при использовании Windows.

Как мне полностью избавиться от этого и OneDrive?

Answer 1

используйте этот скрипт для полного удаления Onedrive :

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

Я думаю, что вы пропустили последний шаг, чтобы удалить 4 записи реестра.

Итак, вы можете использовать инсайдерскую сборку, а в проводнике вы видите «Советы / реклама». Чтобы отключить его, откройте параметры обозревателя и снимите флажок "Показать уведомления поставщика синхронизации".