Сортировка / подсчет файла с разделителями табуляции

Question

У меня есть файл с разделителями табуляции с несколькими столбцами. Я хотел бы увеличить количество раз, когда я вижу что-то в столбце A, и печатать данные, связанные со значением в столбце A, в новом столбце B.

Пример:

1 blue                                        
1 green
1 red            
100 blue           
100 red

Я хотел бы выходной файл, который читает

3 1 blue,green,red
2 100 blue,red

Можно ли сделать это с помощью awk или perl?

Answer 1

в awk:

{
  if (count[$1] == "") {
    count[$1] = 1;
    results[$1] = $2;
  } else {
    count[$1] = count[$1] + 1;
    results[$1] = results[$1] "," $2;
  }
}
END {
  for (number in count) {
    print count[number],number,results[number];
  }
}

В результате получается: 2 100 blue,red 3 1 blue,green,red

для вашего образца данных выше.

Порядок результатов может быть не совсем то, что вы хотите, я не уверен, насколько это важно для вас.

Answer 2

Вот то, что я попробовал, это может сработать для вас. ПРИМЕЧАНИЕ: "\011" = символ табуляции, в качестве пробела укажите " " )

awk 'BEGIN { s = "\011"; c = "," ; cnt = 0; all_colors = "" } {
    if ( NR == 1 ) { num = $1; colors[cnt++] = $2 }
    else {
        if ( num != $1 ) {
            for (x=0; x<cnt; x++) {
                all_colors = all_colors colors[x]
                }
            print cnt s num s all_colors; cnt = 0; all_colors = ""
            num = $1; colors[cnt++] = $2
            }
        else { colors[cnt++] = c $2 }
        }
    }
END {
    all_colors = ""
    for (x=0; x<cnt; x++) { all_colors = all_colors colors[x] }
    print cnt s num s all_colors
}' tab_file

   tab_file                output
1       blue          3       1       blue,green,red
1       green         2       100     blue,red
1       red
100     blue
100     red