Как найти одну конкретную папку в Outlook среди очень многих папок?

Question

У меня Outlook 2013 и много папок для всех моих контактов и электронных писем поставщиков, полученных от них. Я хочу, чтобы можно было быстро найти папку без необходимости прослеживать их все. может кто-нибудь помочь мне здесь, пожалуйста

Answer 1

Надстройка Quick Folders делает именно это. Это коммерческий продукт, разработанный моей компанией, но вы можете использовать бесплатную пробную версию, чтобы найти нужные вам папки.

Answer 2

Outlook не предоставляет прямой функциональности для поиска папок. Однако есть обходные пути, которые обсуждаются в другом вопросе о суперпользователе: как найти потерянную папку в Outlook? , Пользователь Loïc MICHEL создал несколько пользовательских сценариев, чтобы помочь в поиске папок

Внешний веб-сайт (thetechieguy.com) также создал решение с подробными инструкциями. Как искать в Outlook имя папки

Надеюсь это поможет

Answer 3

В меню « Найти» или «Выбрать папку» введите ее имя :

1. Установите фокус на вашу активную папку в области навигации, нажав SHIFT+F6 (в зависимости от вашего текущего фокуса, вам может понадобиться нажать ее несколько раз)
2. Как только ваш фокус окажется в области навигации, введите первые несколько букв имени папки, чтобы выбрать его.
3. Ваша текущая папка остается активной папкой, поэтому вы можете легко перемещать сообщения из нее в другую папку.

Примечание. Будут найдены только видимые / развернутые папки. Свернутые подпапки не будут найдены. См. Также Запуск Outlook, когда все папки свернуты / развернуты.

Если вы не хотите, чтобы ваши папки были расширены, и на самом деле хотите открыть определенную папку, просто введя ее имя, то этот макрос VBA из VBOffice поможет.

Private m_Folder As Outlook.MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
  Dim Name$
  Dim Folders As Outlook.Folders

  Set m_Folder = Nothing
  m_Find = ""
  m_Wildcard = False

  Name = InputBox("Find name:", "Search folder")
  If Len(Trim$(Name)) = 0 Then Exit Sub
  m_Find = Name

  m_Find = LCase$(m_Find)
  m_Find = Replace(m_Find, "%", "*")
  m_Wildcard = (InStr(m_Find, "*"))

  Set Folders = Application.Session.Folders
  LoopFolders Folders

  If Not m_Folder Is Nothing Then
    If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
      Set Application.ActiveExplorer.CurrentFolder = m_Folder
    End If
  Else
    MsgBox "Not found", vbInformation
  End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
  Dim F As Outlook.MAPIFolder
  Dim Found As Boolean

  If SpeedUp = False Then DoEvents

  For Each F In Folders
    If m_Wildcard Then
      Found = (LCase$(F.Name) Like m_Find)
    Else
      Found = (LCase$(F.Name) = m_Find)
    End If

    If Found Then
      If StopAtFirstMatch = False Then
        If MsgBox("Found: " & vbCrLf & F.FolderPath & vbCRLF & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
          Found = False
        End If
      End If
    End If
    If Found Then
      Set m_Folder = F
      Exit For
    Else
      LoopFolders F.Folders
      If Not m_Folder Is Nothing Then Exit For
    End If
  Next
End Sub