Как извлечь конкретный столбец из другой рабочей книги, хранящейся в папке, с помощью VBA?

Question

Предположим, у меня есть рабочие книги, и каждая рабочая книга содержит отдельные рабочие листы, и все рабочие листы имеют одинаковое количество строк и столбцов ... для каждого рабочего листа.Я хочу извлечь название столбца "10-11 мая". Это имя столбца является общим для каждого рабочего листа ... так как я могу извлечь столбец "10-11 мая" из каждой книги, хранящейся в той же папке ..

например :

Каждый лист содержит одинаковое количество строк и столбцов, строки = 453 и столбцы = 55 .. Из этого примера изображения я хочу извлечь столбец «10-11 мая» из всех книг, хранящихся в одной папке и хранящихся в разных листах.

Answer 1

Это то, что вы хотите? источник от https://msdn.microsoft.com/en-us/library/office/gg549168(v=office.14).aspx

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range

    ' Create a new workbook and set a variable to the first sheet. 
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Users\Peter\invoices\"

    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1

    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")

    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)

        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName

        ' Set the source range to be A9 through C9.
        ' Modify this range for your workbooks. 
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")

        ' Set the destination range to start at column B and 
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)

        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value

        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count

        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False

        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop

    ' Call AutoFit on the destination sheet so that all 
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub