Просмотр заголовка письма без открытия сообщения

Question

Я хотел бы просматривать заголовки писем из списка сообщений в папке, не открывая сообщение в первую очередь.

Это возможно?

Answer 1

Я лично положил кнопку на панели быстрого доступа Outlook (QAT). Для этого просто нажмите на выпадающий список в верхнем левом углу окна Outlook и выберите «Больше команд ...». В диалоговом окне "Настройка панели быстрого доступа" выберите "Все команды" в списке "от" и добавьте >> кнопку «Параметры сообщения ...» в правый список. Нажмите OK, и вы там.

Теперь вы можете выбрать нужное сообщение в списке и нажать эту новую кнопку на QAT, чтобы отобразить "Заголовки Интернета".

Answer 2

Определите кнопку для вызова следующего макроса VBA для отображения заголовка текущей выбранной почты:

Public Sub mailHeaderView()
    Dim exp As Explorer
    Dim sel As Selection
    Dim please As String
    Dim s As String
    Dim mi As Outlook.mailItem
    Dim TransportMessageHeadersSchema As String

    ' https://social.msdn.microsoft.com/Forums/vstudio/en-US/e9342b09-02ba-441f-a824-5186bd9835a9/mailitemread-event?forum=outlookdev
    TransportMessageHeadersSchema = "http://schemas.microsoft.com/mapi/proptag/0x007D001E"

    Set exp = Application.ActiveExplorer

    If exp Is Nothing Then
      MsgBox "No Explorer!"
    Else
      Set sel = exp.Selection

      please = " Please select one Mail!"
      If sel Is Nothing Then
        MsgBox "No Selection!" & please
      ElseIf sel.count > 1 Then
        MsgBox "Multiple selection!" & please
      ElseIf sel.count < 1 Then
        MsgBox "No Selection!" & please
      ElseIf sel.item(1).Class <> olMail Then
        MsgBox "No Mail selected!" & please
      Else
        Set mi = sel.item(1)

        If mi Is Nothing Then
          MsgBox "No mail selected!"
        Else
            s = mi.PropertyAccessor.GetProperty(TransportMessageHeadersSchema)

            MsgBox s, vbInformation, "Mail Header"
        End If
      End If
    End If
End Sub

Подобный макрос описан здесь. Вместо того, чтобы открывать MsgBox , почтовый заголовок может быть показан как почта или как текстовый файл через текстовый редактор или веб-браузер.