Обработка файлов Excel

Question

У меня есть 40-50 файлов Excel, которые содержат полезную информацию в первых ячейках 20х25, а затем в ненужных за пределами этих ячеек. Какой самый простой способ очистить мусор от всех файлов одним махом, чтобы остались только первые 20x25 ячеек? Могу ли я сделать это с помощью Powershell в Windows?

Answer 1

ИМХО самый простой способ сделать это - макрос VBA в Excel:

Sub CleanFiles()
' for each file in a directory
'    open it, delete all cell content around the first 20x25 cells, write it back
' 2015-10-15

    Dim path As String, aFile As String
    Dim arr As Variant

    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    Application.EnableEvents = False

    path = "D:\TEMP\xls\"          ' must have trailing backslash
    aFile = Dir(path & "*.xls")
    Do While aFile <> ""
        Application.StatusBar = aFile
        aFile = path & aFile
        Workbooks.Open (aFile)

        ' process file content
        arr = ActiveSheet.Range("A1:Y20")
        Cells.Clear
        ActiveSheet.Range("A1:Y20") = arr

        ' save and close WB
        ActiveWorkbook.Close True, aFile
        aFile = Dir
    Loop

    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    Application.EnableEvents = False
    Application.StatusBar = False
End Sub

Во-первых, обновление экрана и автоматические макросы отключены. Затем сканируется определенная папка для файлов «* .xls» и открывается каждый файл. Содержимое сохраняемой области сохраняется внутри, затем весь лист очищается, а содержимое записывается обратно на лист. При закрытии файла он сохраняется без запроса.

Answer 2

Вы можете сделать Get-Content file.csv | select -First 25 | Export-Csv newfile.csv если вы имеете в виду первые 20-25 строк. Вы можете сделать Get-Content -Header @("a","b","c") file.csv | Select a,b,c | Export-Csv newfile.csv и т.д. В этом порядке, чтобы выбрать весь путь через y, который будет вашим 25-м столбцом. Там может быть лучший способ, хотя.