Поиск уникальных значений в 3 столбцах

Question

У меня есть 3 колонки в Excel. Я хочу найти уникальные значения в столбцах A, B и C.

Так:

1. Посмотрев в столбце A, я хочу найти уникальные значения, которых нет в B или C.
2. посмотрев в столбце B, я хочу найти уникальные значения, которых нет в столбце A или C.
3. просматривая столбец C, я хочу найти уникальные значения, которых нет в столбце A или B.

Это то, что я положил в столбце А

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3) 

Это то, что я положил в столбце B

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Это то, что я положил в столбце C

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Это дает мне повторяющиеся значения в трех столбцах, которые мне нужны, чтобы они были уникальными. Может быть, я просто делаю это очень сложно. Есть идеи, как это сделать?

Пример таблицы:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

В этом случае я хочу уникальный # в каждом столбце. Таким образом, для столбца A уникальные значения, которых нет в столбцах B или C, равны = 1,4,5,6. В столбце B уникальные значения, которых нет в A или C, равны = 8,9, 10. В столбце C уникальные значения, которых нет в B или C: = 11, 12, 13. Я хочу сделать формулу в столбцах D, E, F для этих трех формул.

---

ABC 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

В этом случае я хочу уникальный # в каждом столбце. Таким образом, для столбца A непопулярные значения, которых нет в столбцах B или C, равны = 1,4,5,6. В столбце B уникальные значения, которых нет в A или C, равны = 8,9, 10. В столбце C уникальные значения, которых нет в B или C, равны = 11, 12, 13. Я хочу сделать формулу в столбце D, E, F для этих трех формул.

Answer 1

Вы можете использовать формулу массива ^† как в D1:

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

Формулы в других столбцах похожи:

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

И из вашего примера таблицы я получаю эти:

Если ваша формула начинается с строки, отличной от первой, формулу нужно будет немного изменить, поскольку она использует ROW() которая зависит от строки, в которой находится формула.

^† Примечание: чтобы использовать формулу, вы должны нажать и удерживать Ctrl+Shift, а затем нажать Enter после ее вставки.