рекурсивное сравнение содержимого directoreis по cmd windows xp с выходным файлом

Question

Я хочу сравнить два файла каталогов и подкаталогов рекурсивно, без дополнительной установки в Windows XP. дерево имен папок и файлов одно и то же, но содержимое файлов может отличаться. Есть ли способ сделать это? Спасибо!

Answer 1

Нечто подобное должно сработать, если, как вы сказали, исходное и целевое дерево совпадают:

@ECHO OFF
set myrootfolder1=c:\stack\rootfolder1
set myrootfolder2=c:\stack\rootfolder2
set logfile=c:\stack\compare.log

type NUL > %logfile%

setlocal ENABLEDELAYEDEXPANSION

FOR /R %myrootfolder1% %%G IN (*.*) DO (
    set sourcefile=%%G
    set targetfile=!sourcefile:%myrootfolder1%=%myrootfolder2%!
    echo N | comp /A !sourcefile! !targetfile! | find "OK" > nul
    IF ERRORLEVEL 1 echo !sourcefile! and !targetfile! are different >>%logfile%
)

Это сделает файл журнала следующим образом:

c:\stack\rootfolder1\file1.txt и c:\stack\rootfolder2\file1.txt разные c:\stack\rootfolder1\sub1\file2.txt и c:\stack\rootfolder2\sub1\file2.txt разные

Редактировать: я не использовал здесь fc потому что сообщалось об ошибках в Windows XP, когда команда сравнивала файлы, которые отличаются каждым 128-м байтом строки символов. Моя ссылка: http://support.microsoft.com/kb/953929/en-us

Но следите за комментариями @Synetech для получения дополнительной информации;) спасибо ему!

Answer 2

Я написал эту партию в чистом DOS. Он может сравнивать две папки с подпапками и отображать визуальные сообщения во время сравнения. Это полезно для небольших деревьев папок, поэтому вы можете сразу увидеть ошибки на экране консоли во время сравнения.

Примечание: сравнение будет приостановлено, если произойдет ошибка сравнения! Он не создает журнал ошибок, однако возможно перенаправить эхо-ошибку в файл журнала и отключить команду Pause.

Для деревьев или содержимого больших папок лучше использовать специальные инструменты, такие как ROBOCOPY или аналогичные, которые создают очень подробные отчеты как для копирования, так и для сравнения.

@Echo OFF
echo.
echo  Compares Files in two or more Folders or Paths
echo ================================================
echo.

set /P Src= Digit or Paste HERE Path n.1 : 
::set Src=YourPath
echo.
set /P Dst= Digit or Paste HERE Path n.2 : 
::set Dst=YourPath
echo.
PAUSE
echo.

SETLOCAL EnableDelayedExpansion

FOR /R "%Src%" %%A IN (*.*) DO (
  set SFold="%%A"
  set TFold=!SFold:%Src%=%Dst%!
  set P1="%%~dpA"

  if "!P2!" EQU "" set P2=!P1!
  if "!P1!" NEQ "!P2!" echo ----------------------------------------------------- Compare Folder is Changed & echo.
  FC !SFold! !TFold!
  if !ERRORLEVEL! NEQ 0 echo. - ERROR - ==================================================================== & PAUSE
  set P2=!P1!
)
echo.
echo ====================================
echo      COMPARE TERMINATED . . . .
echo ====================================
echo.
PAUSE

Answer 3

Спасибо GD, я нашел это: Сравнительные папки - dir1 и dir2 находятся на диске D. Файл logfile.txt для сопоставимых результатов также находится на диске D. в командном файле:

  D:
setlocal enableextensions 
setlocal ENABLEDELAYED EXPANSION 
SETLOCAL ENABLEDELAYEDEXPANSION
set filename=logfile.txt
echo. 2>%filename%
cd dir1
(for /r %%i in (*) do set p=%%i&if exist "D:\dir2\!p:~8!" (FC "%%i" "D:\dir2\!p:~8!" | FIND "FC: no dif" > nul&IF ERRORLEVEL 1 (echo !!! file %%i is different >> d:\%filename%)) else (echo !!! file"D:\dir2\!p:~8!" not found >> d:\%filename%))>nul
cd ..\dir2
(for /r %%i in (*) do set p=%%i&if not exist "D:\dir1\!p:~8!"   (echo !!! file "D:\dir1\!p:~8!"  not found >> d:\%filename%))>nul
cd ..
start %filename%