Remote Desktopping - 1 компьютерный контроль 30

Question

Есть ли решение для удаленного рабочего стола, которое позволит одному компьютеру управлять 30? У меня в компьютерном классе 30 компьютеров учеников, и все они показывают одну и ту же веб-страницу Я хочу, чтобы учитель мог нажать кнопку входа в систему и один раз ввести свои учетные данные вместо того, чтобы идти к каждому компьютеру и вводить его 30 раз.

Любое предложение будет полезно.

Answer 1

Я покажу вам, как я это сделаю: (у меня есть небольшой скрипт-автологин для моего роутера, который я использовал здесь)

Установите AutoHotkey на все компьютеры.

На компьютере учителя создайте на рабочем столе файл с именем autologin.ahk:

mysite=http://192.168.178.1/logincheck.lua  ; the login site
myexpected=/home/home.lua                   ; part of the url after login
myuser=username                             ; username
mypass=password                             ; password

oIE:=ComObjCreate("InternetExplorer.Application")
oIE.Visible:=True
oIE.top:=oIE.left:=0, oIE.width:=A_ScreenWidth, oIE.height:=A_ScreenHeight
oIE.Navigate(mysite)
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

oForm:=oIE.document.getElementById("uiMainForm")    ; change this
oForm.elements.item("username").value:=myuser       ; change this
oForm.elements.item("uiPass").value:=mypass         ; change this
oForm.elements.item("uiSubmitLogin").Click()        ; change this
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

url:=oIE.LocationUrl
StringGetPos, pos, url, %myexpected%
if pos=-1
Loop
{
  Getkeystate, state, SPACE, P
  if state=D
    Break
  SoundBeep, 750, 500
  Sleep 50
}

Вам необходимо настроить переменную формы для вашего сайта. Если вход в систему не удастся, он будет подавать звуковые сигналы и продолжать звучать, пока вы не нажмете пробел. Вы можете проверить этот скрипт на компьютере учителя.

Теперь создайте checker.ahk:

script=\\teachers_computer\shared_folder\autologin.ahk
loop
{
  IfExist, %script%
  {
    run %script%
    sleep, 60000  ; 60 seconds
  }
  sleep 10000 ; 10 seconds
}

Запустите это при входе в систему компьютеров учеников. Он будет проверять общую папку на компьютере учителя каждые 10 секунд, если есть autologin.ahk . Если он есть, он будет выполнен и подождет 5 минут. (достаточно времени, чтобы учитель снова удалил файл.)

Учитель может переместить autologin.ahk со своего рабочего стола в общую папку и подождать, пока все компьютеры не войдут в систему (это должно быть в течение 20 секунд). Затем он может переместить файл обратно на рабочий стол, чтобы он больше не был доступен для студентов. Когда несколько компьютеров продолжают подавать звуковые сигналы, он должен перейти к ним и понять, почему логин не работает.

Нет необходимости говорить о том , что оригинал autohotkey.ahk должен быть безопасными (я взять его учитель компьютер безопасен) и файл на короткое время открыт , когда он упал в общей папке (но непосредственно удален впоследствии учитель). Поскольку это делается до того, как студенты прибывают за свои компьютеры, это не должно быть проблемой.