Приложение в стиле Hacker Typer для Windows

Question

Мне нужно сделать несколько скринкастов, демонстрирующих некоторые приемы программирования. Я уже знаю, что я собираюсь напечатать для каждого из них, и я хотел бы свести к минимуму все задержки и неловкость от опечаток и попыток подумать, что я должен был делать дальше.

Существует ли программное обеспечение, которое позволяет мне вставлять кусок текста в буфер, а затем произвольно нажимать на клавиши и выводить мой буфер в текущее активное окно по одному символу за раз? Вроде как родной настраиваемый Хакер Тайпер. Можно ли это сделать с помощью какого-нибудь скрипта AutoHotkey или чего-то подобного? Предложения для приложений для других платформ приветствуются, если их нет для платформы Windows.

Answer 1

Да, вы можете использовать AutoHotKey. Я уверен, что кто-то другой мог бы быстро это сделать, но я, по крайней мере, могу представить возможную структуру сценария:

1. Определите горячую клавишу Suspend и начните приостанавливать ее, чтобы вы могли использовать клавиатуру, когда не хотите затираться. В качестве альтернативы или дополнения используйте #IfWinActive, чтобы ограничить функцию «mashing-keys» одним окном, в котором вы будете это делать.
2. Прочитать текстовый файл в память.
3. Сложите несколько определений горячих клавиш для практически каждой клавиши на клавиатуре для одного действия скрипта.
4. Используйте StringLeft и StringTrimLeft, чтобы получить один символ из вашей большой переменной и удалить его из переменной.
5. Используйте Отправить, чтобы отправить персонажа, которого вы схватили. Возможно, вам придется сделать небольшую замену или условно для обработки отправки {Enter} и {Tab} , но, возможно, нет.

Вот мой сценарий:

#UseHook        ; Avoid loops of the Send command triggering the hotkey again.
AutoTrim, Off   ; Don't auto-trim spaces and tabs from the beginning and end of the sourcetext.
SendMode InputThenPlay  ; Try to prevent the user from corrupting the buffer text.

Suspend, On     ; Start suspended

FileRead, MasherBuffer, magic-button-masher-text.txt
if ErrorLevel
    MasherBuffer = Type or paste text here. You can also drag-and-drop text files here.

Gui, +Resize +MinSize400x200
Gui, Add, Text,, When you are ready, un-suspend this script (Ctrl and `` together will toggle the suspension).`nType any character on the main QWERTY keyboard to send the characters from the buffer instead.
Gui, Add, Edit, vMasherBuffer, %MasherBuffer%
Gui, Show,, Magic Button Masher Buffer
Return

GuiSize:
if ErrorLevel = 1  ; The window has been minimized.  No action needed.
    return
; Otherwise, the window has been resized or maximized. Resize the MasherBuffer control to match.
NewWidth := A_GuiWidth - 20
NewHeight := A_GuiHeight - 50
GuiControl, Move, MasherBuffer, W%NewWidth% H%NewHeight%
return

GuiDropFiles:
Loop, parse, A_GuiEvent, `n
{
    FileRead, AddToBuffer, %A_LoopField%
    MasherBuffer = %MasherBuffer%`n`n%AddToBuffer%
}
GuiControl,, MasherBuffer, %MasherBuffer%
return

^`::Suspend

!`::Gui, Show,, Magic Button Masher Buffer

;   #IfWinActive ahk_class Notepad  ; This limits the button masher to Notepad.
`::
1::
2::
3::
4::
5::
6::
7::
8::
9::
0::
-::
=::
q::
w::
e::
r::
t::
y::
u::
i::
o::
p::
[::
]::
\::
a::
s::
d::
f::
g::
h::
j::
k::
l::
`;::
'::
z::
x::
c::
v::
b::
n::
m::
,::
.::
/::
Space::
GuiControlGet, MasherBuffer
StringLeft, outbound, MasherBuffer, 1
StringTrimLeft, MasherBuffer, MasherBuffer, 1
GuiControl,, MasherBuffer, %MasherBuffer%
if outbound = %A_Space%
    Send {Space}
else if outbound = %A_Tab%
    Send {Tab}
else
    Send {%outbound%}
return

Это можно сделать только в Блокноте, раскомментировав бит #IfWinActive.

У меня Ctrl+` определен как горячая клавиша для приостановки скрипта.

Answer 2

Я написал то, что описал Дейн. Это должно сделать свое дело. Он читает текстовый файл, разбивает строку, затем вводит символы этой строки один за другим с настраиваемой задержкой.

FileRead, text, C:\test.txt
/* Alternatively:
text =
(ltrim
this is the first sentence.
sentence 2 here.
sentence 3 hello.
sentence 4 reporting in.
)
*/

pos := 1
StringSplit, lines, text, `n

^Space:: ; Ctrl + Space
    line := lines%pos%
    loop, Parse, line
    {
        SendInput % A_Loopfield
        Sleep 100 ; Adjust this for delay between keys
    }
    ++pos
Return

Я не был слишком уверен в "затирании" кнопок, поэтому я не включил ничего в этом отношении.