Как получить имя файла только без пути в командной строке Windows?

Question

for /r %f in (*) do echo %f

Дает выходное имя файла вместе со всем путем

\path\to\dir\<filename>

Как получить только <filename> без включенного пути? Мне нужно использовать эту строку имени файла.

Кроме того, возможно ли сделать следующее после получения имени файла?

for /r %%f in (*) do (
echo "blah blah blah 'filename'" >> blahblah_filename.txt
)

Answer 1

Используйте %~nxf для <filename>.<extension> .

И да, вы можете сделать:

for /r %%f in (*) do (
echo "blah blah blah '%%~nxf'" >> blahblah_%%~nxf.txt
)

Смотрите for /?:

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

    %~I         - expands %I removing any surrounding quotes (")
    %~fI        - expands %I to a fully qualified path name
    %~dI        - expands %I to a drive letter only
    %~pI        - expands %I to a path only
    %~nI        - expands %I to a file name only
    %~xI        - expands %I to a file extension only
    %~sI        - expanded path contains short names only
    %~aI        - expands %I to file attributes of file
    %~tI        - expands %I to date/time of file
    %~zI        - expands %I to size of file
    %~$PATH:I   - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI       - expands %I to a drive letter and path only
    %~nxI       - expands %I to a file name and extension only
    %~fsI       - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI     - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values.  The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.

Answer 2

Я пока не могу комментировать, но считаю, что следует отметить следующее, чтобы избежать путаницы.

Хотя f можно использовать как имя переменной FOR, лучше использовать другую букву, чтобы не путать ее с форматной буквой f (которая, как указано в ответе Боба, возвращает полное имя пути), или, по крайней мере, использовать заглавную букву F