ZSH: меню выбора автозаполнения для поиска по истории

Question

ZSH имеет мощное меню выбора автозаполнения, например, для выбора каталога, выбора процесса с помощью kill (kill [tab] [tab]). Вы можете использовать стрелки для перемещения по выбору.

Можно ли иметь всплывающее меню для поиска по истории (CTRL+R)? Таким образом, что меню позволит перемещаться по совпадениям текущей строки поиска CTRL+R?

Answer 1

zsh-navigation-tools делает что-то вроде этого. Если вы используете oh-my-zsh, вам просто нужно добавить zsh-navigation-tools в plugins=(...) в вашем .zshrc тогда ctrl-R выдаст вам историю прокрутки с вверх / вниз и поиском / фильтрацией. Вы можете использовать его без oh-my-zsh, но настройка выглядит как дополнительная работа.

Answer 2

1. Не то, что я знаю из.

2. Возможно, вы захотите попробовать predict-on , который связан с тем, что вы спрашиваете

   autoload -U predict-on
   zle -N predict-on
   zle -N predict-off
   bindkey '^X1' predict-on
   bindkey '^X2' predict-off
   

Answer 3

Это возможно; В принципе, я изменил завершение _kill чтобы оно работало и для исторических событий.

Вот пример; После выбора записи вы нажимаете [ENTER] один раз, чтобы принять номер события (командная строка читает, например, hc 780), и снова нажимаете [ENTER], чтобы выполнить команду. (Используйте fc вместо hc если вы хотите изменить командную строку перед выполнением).

$ hc Makefile[TAB]
history event
 1906  9.3.2013 18:10  vi Makefile
 1867  9.3.2013 17:26  less Makefile
  780  3.2.2013 17:54  cat Makefile                
  776  3.2.2013 17:51  cat ../Makefile     

Чтобы использовать его, поместите добавленные файлы в каталог в вашем $fpath и добавьте эти строки в ваш ~/.zshrc:

zstyle ':completion:*:historyevent' command 'fc -dE -lr 1'
zstyle ':completion:*:historyevent' sort no

Наконец, начните новый сеанс zsh .

Осторожно, это быстрое и грязное решение, но какое-то время оно работало хорошо.

---

_historyevent

#autoload

local out histevent list expl match desc listargs all nm ret=1

_tags historyevent || return 1

all=(-U)
match="*[[:blank:]]*[[/[:blank:]]$PREFIX*$SUFFIX*"
nm="$compstate[nmatches]"

out=( "${(@f)$(_call_program historyevent fc -l 2>/dev/null)}" )
desc="$out[1]"
out=( "${(@M)out[2,-1]:#${~match}}" )

histevent=( "${(@)${(@M)out##[^0-9]#[0-9]#}##*[[:blank:]]}" )

if zstyle -T ":completion:${curcontext}:historyevent" verbose; then
  list=( "${(@Mr:COLUMNS-1:)out}" )
  desc=(-ld list)
else
  desc=()
fi

_wanted processes expl 'history event' \
    compadd "$@" "$desc[@]" "$all[@]" -a - histevent && ret=0

if [[ -n "$all" ]]; then
  zstyle -s ":completion:${curcontext}:historyevent" insert-ids out || out=menu

  case "$out" in
  menu)   compstate[insert]=menu ;;
  single) [[ $compstate[nmatches] -ne nm+1 ]] && compstate[insert]= ;;
  *)      [[ ${#:-$PREFIX$SUFFIX} -gt ${#compstate[unambiguous]} ]] &&
              compstate[insert]=menu ;;
  esac
fi

return ret

_fc

#compdef fc

local curcontext="$curcontext" line state ret=1

_arguments -C \
   '-e[editor command]' \
   '-l[list last history events]' \
   '-n[suppress numbers]' \
   '-r[reverse order]' \
   '*:history event:->historyevent' && ret=0

if [[ -n "$state" ]]; then
  _alternative \
    'historyevent:: _historyevent' && ret=0
fi

return ret