Можно ли создать макрос, который будет предлагать раскрывающееся меню для субъектов в Outlook 2010?

Question

Мне нужна тема в моих сообщениях Outlook, чтобы начать работу с сообщениями. Поскольку в каждый конкретный момент времени выполняется около дюжины заданий, неудобно либо вводить имя задания, либо копировать и вставлять из другого сообщения. Я работал с макросом с кнопкой в меню Outlook, которая создает новое сообщение, но сейчас я застрял с одной работой в качестве темы, и не нашел, как дать мне выпадающее меню все возможные имена работы. Таким образом, любая помощь будет принята с благодарностью.

Answer 1

Попробуйте что-то вроде этого. Обязательно иметь открытый элемент при запуске.

http://www.vbaexpress.com/kb/getarticle.php?kb_id=369

http://www.vbaexpress.com/kb/getarticle.php?kb_id=303

'** The following code goes in a userform **

' Adapted for a single choice

Private Sub cmdOkay_Click()
Dim i As Long
Dim msg As String
Dim Check As String

Dim currItem As MailItem

'Generate a list of the selected items
With ListBox1
    For i = 0 To .ListCount - 1
        If .Selected(i) Then
            msg = .List(i)
            Exit For
        End If
    Next i
End With

If msg = vbNullString Then
    'If nothing was selected, tell user and let them try again
    MsgBox "Nothing was selected!  Please make a selection!"
    Exit Sub

Else

    Set currItem = Application.ActiveInspector.currentItem
    currItem.Subject = msg
    Unload Me

End If

End Sub

Private Sub cmdCancel_Click()
Unload Me
End Sub

Private Sub UserForm_Initialize()

With Me.ListBox1
     'Clear the rowsource in case it has been set
    .RowSource = ""
     'Add the items
    .AddItem ("Cat")
    .AddItem ("Dog")
    .AddItem ("Gerbil")
    .AddItem ("Lizard")
    .AddItem ("Rat")
    .AddItem ("Snake")
    .AddItem ("Turtle")
End With

End Sub


 '** The following code goes in a standard module **

Sub Launch()
'This code will launch the userform
    UserForm1.Show
End Sub