Извлечение элемента из списка в Excel

Question

Как я могу получить данные из перечисленного списка?

Например, если я введу 3 в ячейку A1 , я бы хотел, чтобы в ячейке B1 отображалось "марш".

A1  3
B1  =FX(A1,"january,february,march,april,may")

Любая функция доступна для этого? В списке может быть что угодно.

Answer 1

Вот несколько способов, которые вы можете попробовать:

---

МЕТОД № 1: ФУНКЦИЯ ТЕКСТА ()

Это будет работать только если вы работаете с месяцами. В ячейку B1 введите:

=TEXT(DATE(2000,A1,1),"mmmm")

Вы можете заменить 2000 на любой номер года. Если вы хотите использовать текущий год, замените 2000 на YEAR(NOW()) , хотя на самом деле не должно иметь значения, какой год вы используете.

---

МЕТОД № 2: ВЫБРАТЬ () ФУНКЦИЯ

В ячейку B1 введите:

=CHOOSE(A1,"January","February","March","April","May","June","July","August",
           "September","October","November","December")

Ввод этой формулы может быть утомительным. Чтобы сделать это немного быстрее, вы можете попробовать ff. шаги:

1. Введите "Январь" в пустую ячейку и перетащите ячейки Fill Handle 12 вправо, пока ячейки не будут заполнены месяцами.

   

2. В ячейке B1 введите = и выберите ячейки, содержащие названия месяцев.

   

3. Нажмите F9. Вы получите формулу, которая выглядит следующим образом:

   ={"January","February","March","April","May","June","July","August"," September","October","November","December"}

4. Отредактируйте формулу, чтобы включить функцию CHOOSE() .

---

МЕТОД № 3: ИНДЕКС () и именованный диапазон

1. Создайте именованный диапазон. Для этого перейдите в Формулы > Определить имя.
2. Введите предпочитаемое имя в поле Имя. В моем случае я использовал месяцы.

3. Введите FF. формула в поле « Относится к» (для этого вы также можете использовать * вспомогательный диапазон ***):

   ={"January";"February";"March";"April";"May";"June";"July";"August"; "September";"October";"November";"December"}

   У вас будет что-то вроде этого:

   

4. В ячейке B1 используйте ff. формула:

   =INDEX(months,A1,1)

*** Например, если вы решите ввести месяцы в ячейках от D1 до D12. В поле «Относится к» введите =D1:D12 .*

Answer 2

Это просто ключ, определение значения с поиском ключа (и возвращением значения). Используйте другой лист для этого списка и используйте VLOOKUP на первом листе.

В этом случае ключ равен 3 а значение - march , так что это будет на Листе 2:

A1 = 3
B1 = "march"

а затем на листе 1:

A1 = 3
B1 = VLOOKUP(A1;Sheet1!A:B;2;FALSE)

Answer 3

Вы можете использовать функцию vlookup.
Введите в листе 2
A1 1
В1 Янв
A2 2
B2 февраль
А3 3
B3 мар

и т.п.

Теперь введите формулу = VLOOKUP(A1, Sheet2!$ A $ 1:$ B $ 12,2, FALSE)
В ячейке В1 Лист1.
Скопируйте эту формулу в ячейки ниже B1.
Теперь введите значения месяца в ячейках ниже A1. Они будут декодированы в соответствующих ячейках в столбце B.

Answer 4

Другие ответы, предоставленные на данный момент, предлагают вам реорганизовать ваши данные в формат, более подходящий для встроенных функций Excel, и для этого есть веские причины, но если вам действительно нужно, чтобы ваши данные были в текстовой строке, разделенной запятыми, сработает следующее:

A1   3
A2   january,february,march,april,may
A3   =IFERROR(MID(A2,FIND("_",SUBSTITUTE(","&A2&",",",","_",A1)),FIND("_",SUBSTITUTE(","&A2&",",",","_",A1+1))-FIND("_",SUBSTITUTE(","&A2&",",",","_",A1))-1),"[Out of bounds]")

Вы можете заменить "_" на любой другой символ, который не появится в вашем списке.