VBA - всплывающие команды для подробного заполнения таблицы

Question

Я могу успешно найти конкретную строку (по ссылке в столбце A), скопировать строку и вставить ее под оригинал.

Теперь мне нужна возможность запрашивать информацию для заполнения определенных ячеек. Например.

1. Найдите строку 7, скопируйте и вставьте в строку 8.
2. Затем откройте всплывающее окно "Обновить информацию о задании" и введите его в ячейку G8.

Этот шаблон всегда один и тот же, то есть обновлять столбец G в тех строках, в которые он вставлен.

Любая помощь с благодарностью.

Answer 1

В качестве дополнения к моему ответу на ваш последний вопрос, вот макрос снова с добавлением приглашения для ввода данных.

Sub CopyData()
    Dim res As String
    Dim cl As Range
    Dim sh As Worksheet

    ' operate on the active sheet
    Set sh = ActiveSheet

    ' ask for ID to find in column A
    res = InputBox("Enter ID to Find", "Copy Row")

    ' If no responce, exit
    If res = "" Then
        Exit Sub
    End If

    With sh
        ' Find first occurance
        Application.FindFormat.Clear
        Set cl = .Columns(1).Find(What:=res, _
            After:=.Cells(.Rows.Count, 1), _
            LookIn:=xlValues, _
            LookAt:=xlWhole, _
            SearchOrder:=xlByRows, _
            SearchDirection:=xlNext, _
            MatchCase:=True)

        If Not cl Is Nothing Then
            ' if found, select entire row
            Set cl = cl.EntireRow
            ' copy and insert paste data into next row
            cl.Copy
            cl.Offset(1, 0).Insert
            ' turn off copy highlight (moving border)
            Application.CutCopyMode = False

            ' Prompt for input
            res = InputBox("Enter some info for Column G", "Update job information")
            If res <> "" Then
                cl.Cells(2, 7) = res
            End If
        End If
    End With
End Sub