Переключение между DHCP и статическим IP

Question

Мой ноутбук должен использовать DHCP дома и статический IP на работе. Насколько я могу судить, нет возможности быстро переключаться между ними - мне придется вручную настраивать сетевое соединение каждый раз, когда я перемещаю ноутбук. Одной из альтернатив может быть создание небольшого Bash-скрипта для редактирования /etc/network/interfaces , но я бы предпочел более простой способ, например, Настройки сетевого прокси → Расположение.

Редактировать: Похоже, это может быть просто с использованием /etc/network/interfaces.

Answer 1

Это можно легко сделать с помощью NCD, программного обеспечения для настройки сети, которое я разрабатываю: http://code.google.com/p/badvpn/wiki/NCD

Следующая программа NCD использует либо статическую конфигурацию, либо DHCP на основе значения переменной. Для переключения необходимо отредактировать программу NCD и перезапустить демон NCD. (но см. ниже для автоматического обнаружения)

process lan {
    # Network device name.
    var("eth0") dev;

    # Use static config or DHCP? Change to "true" for static config.
    var("false") is_home;

    # Wait for device and link.
    net.backend.waitdevice(dev);
    net.up(dev);
    net.backend.waitlink(dev);

    # Get configuration.
    provide("lan_config");
    depend("lan_config_done") config;

    # Assign IP address.
    net.ipv4.addr(dev, config.addr, config.addr_prefix);

    # Add default route.
    net.ipv4.route("0.0.0.0", "0", config.gateway, "20", dev);

    # Configure DNS servers.
    net.dns(config.dns_servers, "20");
}

process lan_config_home {
    depend("lan_config") dep;
    if(dep.is_home);

    # Choose static configuration.
    var("192.168.1.72") addr;
    var("24") addr_prefix;
    var("192.168.1.1") gateway;
    list("192.168.1.1") dns_servers;

    provide("lan_config_done");
}

process lan_config_other {
    depend("lan_config") dep;
    ifnot(dep.is_home);

    # Do DHCP.
    net.ipv4.dhcp(dep.dev) dhcp;

    # Verify address.
    ip_in_network(dhcp.addr, "127.0.0.0", "8") test_local;
    ifnot(test_local);

    # Alias configuration from DHCP.
    var(dhcp.addr) addr;
    var(dhcp.prefix) addr_prefix;
    var(dhcp.gateway) gateway;
    var(dhcp.dns_servers) dns_servers;

    provide("lan_config_done");
}

Выбор также может быть автоматизирован путем проверки MAC-адреса сервера DHCP. Следующая программа NCD всегда выполняет DHCP, но затем сравнивает MAC-адрес DHCP-сервера с адресом домашнего маршрутизатора. Если они совпадают, он игнорирует полученный по DHCP адрес и назначает статический адрес, в противном случае он назначает адрес DHCP. (примечание: для этого вам нужен последний NCD из репозитория svn, я только что реализовал переменную dhcp.server_mac )

process lan {
    # Network device name.
    var("eth0") dev;

    # MAC address of home router (6 two-digit caps hexadecimal values separated with colons).
    var("00:AB:CD:EF:51:74") home_mac;

    # Wait for device and link.
    net.backend.waitdevice(dev);
    net.up(dev);
    net.backend.waitlink(dev);

    # Do DHCP.
    net.ipv4.dhcp(dev) dhcp;

    # Are we home?
    strcmp(dhcp.server_mac, home_mac) is_home;

    # Choose configuration.
    provide("lan_config");
    depend("lan_config_done") config;

    # Assign IP address.
    net.ipv4.addr(dev, config.addr, config.addr_prefix);

    # Add default route.
    net.ipv4.route("0.0.0.0", "0", config.gateway, "20", dev);

    # Configure DNS servers.
    net.dns(config.dns_servers, "20");
}

process lan_config_home {
    depend("lan_config") dep;
    if(dep.is_home);

    println("using config: static");

    # Choose static configuration.
    var("192.168.1.72") addr;
    var("24") addr_prefix;
    var("192.168.1.1") gateway;
    list("192.168.1.1") dns_servers;

    provide("lan_config_done");
}

process lan_config_other {
    depend("lan_config") dep;
    ifnot(dep.is_home);

    println("using config: dhcp");

    # Verify address.
    ip_in_network(dep.dhcp.addr, "127.0.0.0", "8") test_local;
    ifnot(test_local);

    # Alias configuration from DHCP.
    var(dep.dhcp.addr) addr;
    var(dep.dhcp.prefix) addr_prefix;
    var(dep.dhcp.gateway) gateway;
    var(dep.dhcp.dns_servers) dns_servers;

    provide("lan_config_done");
}