Сделано с ddrescue.
Я думаю, нет.
6 ответов
4
Если вам нужно только прочитать из него, вы можете использовать EXT $ Unpacker, который является бесплатным и с открытым исходным кодом.
4
Возможным решением будет использование VMWare для создания виртуальной машины на W7. Установите вашу любимую ОС Linux, затем смонтируйте образ для доступа к ней, или импортируйте как файл, затем смонтируйте.
Затем вы можете настроить общий ресурс Samba/CIFS и доступ из W7.
0
Почему бы и нет? Это просто изображение.
Вы можете использовать FTK IMAGER, скачать здесь
- Новая функция позволяет пользователям монтировать образ как диск или физическое устройство.
- FTK Imager 3.0 теперь поддерживает файловые системы VXFS, exFAT и Ext4.
- Безопасно смонтируйте криминалистический образ (AFF/DD/RAW/001/E01/S01) как физическое устройство или логически как букву диска.
0
Вы можете установить ext2fsd, который установит драйверы, которые ваш компьютер Windows должен будет распознать ext. Затем вы можете смонтировать образ с помощью монтажного инструмента, такого как Mount Image Pro или FTK Imager.
0
OSFMount http://www.osforensics.com/tools/mount-disk-images.html
OSFMount позволяет монтировать локальные файлы образов дисков в Windows с буквой диска.
Прекрасно работает для монтирования образа Ext4 в Windows, загрузка всего 2 МБ.
О других:
Mount Image Pro v6 [ https://dailyuploads.net/ewmo7ypfr1m5] (^ - запуск этой версии возможен только при использовании патча Anti Dongle)
НО Mount Image Pro не может монтировать файлы Ext4 (это просто хорошо для * .iso, * .dmg, * .vhd и некоторых других судебных образов)FTK Imager 3.4.3 http://ad-exe.s3.amazonaws.com/AccessData_FTK_Imager_3.4.3_x64.exe Ну, я похож на одну историю - все виды поддержки CD-образов, но ни одной для Ext4
OSFMount не имеет поддержки drop'n'drag - также использование OSFMount.com не так просто, чтобы легко связать его с файлами * .ext4 или * .img для их монтирования. (требуется добавление параметров) Итак, вот cmd-скрипт OSFMount.cmd
@prompt -$G
@echo OSFMount Script 1.0
@echo ===================
@echo.
@set OSFMount_Exe=OSFMount.com
@set OSFMount_Path="%programFiles%\OSFMount\%OSFMount_Exe%"
@set MaxDrivesCount=4
@set MountPoint=#:
@set options=ro
@set g_MuteOutput= ^>nul 2^>^&1
@Call :CheckNSet_PathToExe
@Call :MayBe_UnMountAll
::if "%2" NEQ "" set MountPoint=%2
@set File=%1
@set cmd=%OSFMount% -a -t file -m %MountPoint% -f "%File%" -o %options%
@%cmd%
@if Errorlevel 1 @(
@echo Errorlevel: %Errorlevel%
@call :UnMountAll
%cmd%
)
:: %g_MuteOutput%
:: @pause
@goto :eof
:CheckNSet_PathToExe
@call :SetIfExist OSFMount %OSFMount_Path%
@if not defined OSFMount @(
@call :SetIfExist OSFMount "%~dp0%OSFMount_Exe%"
@if not defined OSFMount @(
@echo ERROR: %OSFMount% not found!
@echo.
@echo Please copy %~nx0 into same dir where %OSFMount_Exe% is!
@exit
)
)
@goto :eof
:SetIfExist
@if exist "%~2" set %1="%~2"
@goto :eof
:MayBe_UnMountAll
:: GetNumberOf (EXT4) Drives
:: Well OSFMount can also mount other types but this is some kind of compromise or now
@set g_CountLines= ^^^| find /c "="
@set g_Drives=wmic logicaldisk where FileSystem^^^="EXT4" get Name /value
@for /f %%x in ('%g_Drives% %g_CountLines%') do @set Lines=%%x
@echo Currently mounted drives %Lines% \ %MaxDrivesCount%
@if %lines% GEQ %MaxDrivesCount% @call :UnMountAll
@goto :eof
:UnMountAll
@for /f "tokens=2 delims==" %%d in (
'%g_Drives%'
) do @(
@call :UnMount %%d
)
@prompt -$G
@goto :eof
:UnMount
@%OSFMount% -D -m %1 %g_MuteOutput%
@if not errorlevel 1 @echo %1 UnMounted!
@goto :eof
Монтаж:
- Скопируйте / вставьте и сохраните его как OSFMount.cmd (в Блокноте или другом редакторе)
- и поместите его в тот же каталог, что и OSFMount.com. (Хорошо, если OSFMount установлен в «C:\program files\OSFMount», вы также можете поместить его в другое место.)
- Создать ссылку на рабочий стол или панель быстрого запуска
Использование:
- Чтобы смонтировать изображение, просто перетащите его на OSFMount.cmd (или его ссылку).
- Связь с файлами также проста - просто выберите OSFMount.cmd в диалоговом окне "Открыть с помощью".
Пример использования командной строки:OSFMount.cmd d:\android-5.1-rc1\system.img
Ну, следующая буква свободного диска выбирается автоматически. Если вы установили более 4-х образов, скрипт сбросит и размонтирует остальные. (Измените строку с MaxDrivesCount = 4 в скрипте, если вам нужно больше или меньше. )
Пока что этот скрипт сделан и протестирован только с ext4 изображениями. Для работы с другими типами изображений, такими как iso, vhd вы, вероятно, можете изменить скрипт.