Как управлять громкостью системы в OS X с помощью клавиатуры без средств управления мультимедиа?

Question

Я использую клавиатуру ПК в Mac OS. Я могу использовать меню для управления громкостью, но есть ли какие-либо сочетания клавиш, которые можно использовать для изменения громкости системы?

Или, может быть, простой скрипт или решение, которое я могу установить, чтобы установить громкость с помощью клавиатуры.

Answer 1

Вы можете купить про версию Sizzling Keys. Это preference pane которая позволяет вам, помимо прочего, определить пользовательское сочетание клавиш для изменения громкости системы.

---

Кроме того, вы можете изменить системный том с помощью AppleScript.

Откройте редактор AppleScript и введите

set volume output volume 100

Объем по шкале от 0 до 100. Вы можете установить абсолютное значение (например, 100 для полного объема) или создать сценарии, которые увеличиваются / уменьшаются, например, следующие:

set vol to output volume of (get volume settings)
if vol > 90 then # 100 max
    set volume output volume 100
else
    set volume output volume (vol + 10)
end if

Для уменьшения громкости:

set vol to output volume of (get volume settings)
if vol < 10 then # 0 is min
    set volume output volume 0
else
    set volume output volume (vol - 10)
end if

Если вы хотите воспроизвести звук обратной связи, который обычно возникает при изменении громкости, вы можете добавить в скрипт следующее:

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

Вы можете сохранить сценарии как приложения или интегрировать их в меню « Службы», используя Automator в качестве службы без ввода данных. Вы можете определить сочетания клавиш для служб в Системных настройках »Клавиатура» Сочетания клавиш »Службы

Answer 2

Карабинер (ранее KeyRemap4MacBook) может переназначать функциональные клавиши для управления громкостью, и до сих пор работал без проблем для меня. В панели управления найдите "F9 для отключения" и т.д.

Answer 3

Я упаковал набор сервисов и инструкций AppleScript, которые позволяют вам контролировать громкость системы и iTunes, а также воспроизводить / приостанавливать & next / prev на любой клавиатуре в Lion.

http://gskinner.com/blog/archives/2011/10/media-keys-in-osx-for-any-keyboard.html

Answer 4

Старый поток, но способ, которым я решил это, состоит в одной строке

Увеличить громкость на 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) + 10)'

Уменьшить громкость на 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) - 10)'

Фактически закончил тем, что написал сообщение в блоге об использовании этого с приложением Альфреда: http://arif.im/system-volume-control-using-alfred/

Answer 5

Клавиши от F1 до F12 на клавиатуре ПК должны делать то же самое. Я предполагаю , что у Вас не было никаких проблем с заменой ключа "Windows" для ⌘ ключа. Если клавиши F1 - F12 не работают, перейдите к системным настройкам, клавиатуре и мыши, клавиатуре и сделайте выбор оттуда, использовать ли клавиши F напрямую или с квалификатором клавиши fn. С уважением, Пол

Answer 6

Вот мое полное решение для ярлыков для увеличения, уменьшения и отключения звука. Я использую приложение Spark для привязки сочетаний клавиш к этим сценариям (http://www.macupdate.com/app/mac/14352/spark). Сценарии проверяют текущее состояние отключения и обрабатывают его, чтобы избежать странных проблем, которые могут возникнуть, если вы не контролируете его должным образом.

Увеличить громкость:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
end if
set vol to output volume of (get volume settings)
if vol > 95 then
    set volume output volume 100
else
    set volume output volume (vol + 5)
end if

do shell script "afplay /System/Library/Sounds/Pop.aiff"

---

Убавить звук:

set vol to output muted of (get volume settings)
if (vol = true) then
    error number -128
else
    set vol to output volume of (get volume settings)
    if vol < 5 then # 0 is min
        set volume with output muted
    else
        set volume output volume (vol - 5)
    end if

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

end if

---

Отключение / включение звука:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
else
    set volume with output muted
end if