Как добавить ярлыки cmd в Windows XP?

Question

Мне часто нужно получить доступ к некоторым программам командной строки, таким как mysql. Есть ли способ назначить этим программам ярлык, чтобы мне больше не требовалось вводить целые пути? Я думаю, что это называется символическими ссылками, но их нет в xp из того, что я прочитал. Но это должно быть как-то возможно, когда я ранее установил MySQL из установщика, «mysql» как ключевое слово для доступа к БД было доступно везде в cmd.

Я попытался возиться с реестром и установить системные переменные за Моим компьютером, но единственным результатом было то, что я мог получить к ним доступ как% xyz%, что не совсем то же самое. Больше ничего не работает.

Спасибо

Answer 1

Вы можете просто добавить каталоги к вашему пути, используя ...

setx path "%path%;c:\foo" -m

Но я обычно делаю очень простой скрипт для каждой команды и называю его с помощью ярлыка, который я хочу использовать. Все мои скрипты помещаются в каталог, который добавляется в путь. Все, что мне нужно сделать, чтобы запустить скрипт, это набрать тот ярлык, какой бы CD я ни находился.

Вы также можете разработать эти сценарии для использования параметров, так что вы можете очень просто выполнять сложные команды, не запоминая их.

Это в основном то, что сценарии все.

Вот пример простого скрипта, который я сделал, который показывает информацию о жестком диске для любой машины в сети, используя команду Sysinternals psinfo.exe. Я сохранил его как driveinfo.cmd , и я могу напечатать driveinfo /? чтобы напомнить мне о синтаксисе.

@echo off

echo.
echo DriveInfo v1.1
REM dependencies:  psinfo.exe
echo.

if [%1] == [] goto :command
if [%1] == [/?] goto :help
setlocal
set parm=%1
for %%U in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
call set "parm=%%parm:%%U=%%U%%"
)
if [%parm:~0,2%] == [\\] goto :command
goto :error

:command
if [%1] == [] (
echo Drive information for %COMPUTERNAME%:
) else (
echo Drive information for %parm:~2%:
)
psinfo -d volume %1 2>nul | findstr /v "System information for" || (
goto :noresponse
)
goto :eof

:error
echo Syntax error
goto :eof

:noresponse
echo.
echo %parm:~2% cannot be found
goto :eof

:help
echo Usage: driveinfo [\\computer]
goto :eof

Answer 2

Сделайте это: получите полный путь к исполняемому файлу mysql и скопируйте его.

Щелкните правой кнопкой мыши "Мой компьютер", затем "Свойства", затем "Дополнительно", затем "Переменные среды".

У вас должна быть переменная с именем PATH. Отредактируйте это. В конце текущей вы добавляете точку с запятой и путь к каталогу, в котором находится ваш исполняемый файл mysql, так что он выглядит как OLDPATH; находится PATHWHEREMYSQLEXECUTABLE

Answer 3

Поскольку вы упоминаете символические ссылки, вы можете скачать инструменты GnuWin32 . Вам понадобится пакет FileUtils, который включает команду "LN". После установки они должны быть в пути. Затем вы можете создавать символические ссылки или жесткие ссылки. Возможно, вы захотите создать папку для размещения ваших ссылок. Эта папка также должна быть в пути.