Синтаксическая ошибка Excel VBA

Question

Я пытаюсь использовать следующий код, который я нашел в Интернете, но он останавливается из-за синтаксической ошибки: см. Ниже

Sub TestCNR()
    Cnr 10, 4
End Sub
Sub Cnr(n, r)
    i = 1
    For j = 1 To r
        Cells(i, j).Value = j
    Next

    Do Until Finished(n, r, i)
        j = FindFirstSmall(n, r, i)
' The error occures in below line
        For k = 1 To j – 1           
            Cells(i + 1, k).Value = Cells(i, k).Value
        Next
        Cells(i + 1, j).Value = Cells(i, j).Value + 1
        For k = j + 1 To r
            Cells(i + 1, k).Value = Cells(i + 1, k - 1).Value + 1
        Next
        i = i + 1
    Loop
End Sub
Function Finished(n, r, i)
    Temp = True

    For j = r To 1 Step -1
        If Cells(i, j).Value <> j + (n - r) Then
            Temp = False
        End If
    Next
    Finished = Temp
End Function

Function FindFirstSmall(n, r, i)
    j = r
    Do Until Cells(i, j).Value <> j + (n - r)
        j = j - 1
    Loop
    FindFirstSmall = j
End Function

Может кто-нибудь посоветовать причину ошибки пожалуйста?

Answer 1

[...] код, который я нашел в сети

For k = 1 To j – 1

Это – символ не является - Не просто скопируйте и вставьте код из Интернета :)

Debug.Print Asc("–")
 150
Debug.Print Asc("-")
 45 

Парсер VBA не распознает Chr$(150) как оператор MINUS : токен недействителен, поэтому синтаксическая ошибка.

К вашему сведению, эти неквалифицированные вызовы Cells неявно ссылаются на то, чем является ActiveSheet ; Вы могли бы хотеть сделать свой целевой лист более явным чем это.