Формула для возврата процента числа до максимального значения

Question

Может кто-нибудь помочь мне построить формулу в Excel? Я близко, но не могу понять, как включить "Максимум 5" и "Максимум 25" для диапазонов> 10-50 и 51+. Смотрите мой график ниже, чтобы рассчитать размер выборки с учетом населения.

Если население:

1
>1 - 10
>10 -50
51+

Размер образца:

1
2
25% of Population up to a Maximum of 5
10% of Population up to a Maximum of 25

Моя формула сейчас, которая не возвращает то, что я хочу:

=IF(G4=1,1,IF(AND(G4>1,G4<=10),2,IF(AND(OR(G4>10,G4<=50),(0.25*G4),AND(G4>50,(0.1*G4),G4>25,25)),IF(G4>5,5)))) 

Answer 1

Я думаю, что это то, что вы ищете, обратите внимание на использование MIN():

=IF(A1=1,1,IF(AND(A1>1,A1<=10),2,IF(AND(A1>10,A1<=50),MIN(5,A1*0.25),IF(A1>=51,MIN(25,0.1*A1)))))

где A1 - стоимость населения.

Answer 2

Я уточнил параметры, изменив макет вашей формулы:

=IF(G4=1,1,
    IF(AND(G4>1,G4<=10),2,
       IF(AND(OR(G4>10,G4<=50),(0.25*G4),
                 AND(G4>50,(0.1*G4),G4>25,25)
             ),IF(G4>5,5)
         )
      )
   ) 

Несколько вещей становятся понятными:

• Последний IF() имеет истинное значение, но не ложное значение.
• Финальное AND() проверяет 4 значения, два условных и два числовых.
• Предыдущее AND() проверяет 3 значения, OR() , числовое и AND() .

Я не уверен, как вы пытались сформулировать свои условия, но явно отсутствуют некоторые условия IF() .

Обратите внимание, что ваши предложения AND() не нужны, поскольку в каждом случае одно из условий неявно, поэтому я бы предложил:

=IF(G4<=1,G4=1,
    IF(G4<=10,2,
       IF(G4<=50,
            IF(G4>20,5,0.25*G4),
            IF(G4>250,25,0.1*G4)
         )
      )
   )

Я добавил, что допускаю размер выборки, равный нулю, если G4 равен нулю или отрицателен. Я сравнил пределы размера популяции, чтобы сэкономить, вычисляя размер выборки дважды (чего также избегает использование Брюсом Уэйном MIN()).