Как указать сетку в терминах ячеек, а не расстояний?

Question

Можно ли указать сетку с точки зрения количества линий сетки, а не как интервал (в PowerPoint 2016)? Я хочу иметь сетку 2х3, чтобы помочь мне спроектировать презентацию, но я могу только найти способ указать сетку с точки зрения расстояния между линиями.

Настройки, которые я нашел:

Answer 1

Вот пример кода со страницы на сайте часто задаваемых вопросов PowerPoint:

Работа с руководствами в PPT 2013 и более поздних версиях http://www.pptfaq.com/FAQ01214-Working-with-Guides-in-PPT-2013-and-later.htm

Если вы не привыкли работать с VBA, в нижней части этой страницы есть ссылка на простое руководство.

Это позволяет добавлять гиды horiz/vert практически в любом месте:

Sub AddGuides()

    Dim HGuides As String
    Dim VGuides As String
    Dim x As Long
    Dim aGuideArray() As String

    ' Edit these to indicate where you'd like to put guides:
    ' Values are in points, 72 points to the inch
    ' Separate each value from the next with a pipe | character

    ' Horizontal guide positions:
    HGuides = "72|144|256.5"
    ' Vertical guide positions:
    VGuides = "10|20|30|40|50|60|70|80|90|100"

    With ActivePresentation
        ' nb ppHorizonatalGuide = 1; ppVerticalGuide = 2
        ' nb to add guides to master rather than slides,
        '   use .SlideMaster.Guides.Add below
        '   in place of .Guides.Add

        ' First add the horizontal guides
        aGuideArray = Split(HGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppHorizontalGuide, CSng(aGuideArray(x))
        Next

        ' and now the vertical guides
        aGuideArray = Split(VGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppVerticalGuide, CSng(aGuideArray(x))
        Next

    End With

End Sub