Формула для увеличения каждой 12-й строки на процент

Question

Я пытаюсь создать формулу для оценки будущих затрат на владение арендуемой собственностью.

Одним из примеров могут быть налоги, в среднем налоги на недвижимость увеличиваются на 4% каждый год, где я живу.

Поэтому я хочу создать формулу для этого и других подобных типов в расчетах.

Все, что я мог найти в Интернете, что это близко, это: =INT((ROW(E4)/12)+144)

Но для каждых 12 строк это просто добавляет 1 номер. Мне нужно, чтобы результат был умножен на 4% по сравнению с предыдущим рядом, и мне не повезло, что я смог его выяснить.

Надеюсь, кто-то может помочь!

Answer 1

Поместите основанную сумму в A1. В B1 введите:

=$A$1*(1+4%*(ROUNDUP(ROW()/12,0)-1))

и скопировать вниз:

Каждые 12 строк базовая сумма увеличивается на фиксированные 4% (без начисления процентов ).

Измените процент в соответствии с вашими потребностями. Измените "12" в формуле, чтобы изменить коэффициент повторения строк. Чтобы получить увеличение до соединения, нужна немного другая формула.

Answer 2

Чтобы сделать это составной частью, поместите начальное значение в A1.

В А2 положите это:

=IF(MOD(ROW()-1,12)=0,A1*1.04,A1)

И скопировать вниз.

---

Если вы хотите основать его на одной ячейке и соединении (аналогично @ Gary'sStudent)

=$A$1*(1.04^INT((ROW()-1)/12))

Answer 3

=IF(MOD(ROW(),12) = 0, INDIRECT(ADDRESS(ROW()-1,COLUMN())) * 1.04, INDIRECT(ADDRESS(ROW()-1,COLUMN())))

Этот условный оператор использует модуль (MOD) номера строки, чтобы выполнить вычисление на 1,04 в каждой 12-й строке. INDIRECT(ADDRESS(ROW()-1,COLUMN())) извлекает значение из указанной выше ячейки, увеличивается на 1,04 (4%), когда условный оператор равен true (т. Е. Строка mod 12 оценивается в 0).