Ярлык Windows Explorer, чтобы перейти к следующей папке родного брата?

Question

Я ищу комбинацию клавиш в Windows 10, которая позволяет мне перемещаться из папки A в папку B из папки A:

- Top Folder
-- A (I am here)
-- B

Ярлык, то:

- Top Folder
-- A 
-- B (now I am here)

Не удалось найти информацию о родном ярлыке для этого.

PS: скрипт AHK тоже будет полезен.

Answer 1

Получил работу с этим замечательным скриптом Autohotkey:

; navigate to next sibling folder from Windows Explorer
#If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass")
^PgUp::
^PgDn:: NavigateToSiblingDir( InStr(A_ThisHotkey, "Up") )

NavigateToSiblingDir(UpDown)  {
   oShell := ComObjCreate("Shell.Application")
   WinGet, hWnd,, A
   for oWin in oShell.Windows  {
      if (hWnd = oWin.hwnd)  {
         oFolder := oWin.Document.Folder
         startDirPath  := oFolder.Self.Path
         parentDirPath := oFolder.ParentFolder.Self.Path
         break
      }
   }

   for item in oShell.Namespace(parentDirPath).Items  {
      if !item.IsFolder
         continue
      if (found && nextSiblingPath := item.Path)
         break
      if (item.Path = startDirPath && found := true)
         prevSiblingPath := prev
      prev := item.Path
   }

   if (UpDown && prevSiblingPath)
      oWin.Navigate(prevSiblingPath)
   if (!UpDown && nextSiblingPath)
      oWin.Navigate(nextSiblingPath)
}

Github: explorer-navigate-sibling-folder.ahk

Моя сердечная благодарность и заслуги передаются teadrinker & jeeswg (AHK).