Есть ли сочетание клавиш "Сохранить в вашей библиотеке" в настольном приложении Spotify?

Question

Save to Your Library - это отличный способ сохранить любимые песни и воспроизвести их позже как плейлист. Также здорово сделать Your Library > Songs доступной в автономном режиме на мобильном телефоне. Тогда ты никогда не будешь без чего-то хорошего слушать.

При прослушивании на моем настольном компьютере я хотел бы без труда добавить текущий трек в мою библиотеку.
Есть ли сочетание клавиш, чтобы это произошло?

Для справки, здесь была похожая функция под названием "Помечено" с устаревшим вопросом SuperUser.

Answer 1

Никакие сочетания клавиш, не говоря уже о Save to Your Library , не встроены в настольные приложения Spotify и, вероятно, никогда не будут. В декабре 2016 года они пометили запрос (первоначально с 2012 года) как "Не сейчас".

Для пользователей MacOS я не знаю решения.

Для пользователей Windows AutoHotkey достаточно работоспособен.

Вот скрипт AutoHotkey, который работает с 10-30-2017.

; Control+Shift+Win+F1
^+#F1:: SendInput {Media_Play_Pause}

; Control+Shift+Win+F2
^+#F2:: SendInput {Media_Prev}

; Control+Shift+Win+F3
^+#F3:: SendInput {Media_Next}

; Control+Shift+Win+F4
^+#F4:: SaveSongToSpotifyLibrary()


SaveSongToSpotifyLibrary() {
  spotify := "ahk_exe spotify.exe"
  if WinExist(spotify) {
    ; Store starting window ID and mouse position.
    MouseGetPos x, y, startingWinId

    ; Activate Spotify.
    WinActivate %spotify%
    WinWaitActive %spotify%

    saveToYourLibraryIcon = %A_WorkingDir%\apps\SpotifyController\SaveToYourLibraryIcon.png
    ImageSearch FoundX, FoundY, 0, 0, A_ScreenWidth, A_ScreenHeight, %saveToYourLibraryIcon%
    if (ErrorLevel = 0) {
      Click %FoundX%, %FoundY%

    } else if (ErrorLevel = 2) {
      MsgBox % "Problem conducting image search. Is the saveToYourLibraryIcon in the correct location?"

    } else if (ErrorLevel = 1) {
      MsgBox % "Unable to save song. Can't find the Add button."
    }

    ; Restore original window and mouse position.
    WinActivate ahk_id %startingWinId%
    MouseMove %x%, %y%
  }
}

инструкции

• Если вы никогда ранее не создавали сценарий, пожалуйста, ознакомьтесь с руководством для начинающих.

• Это использует функцию ImageSearch. Я создал изображение для поиска, сделав снимок экрана с кнопкой «плюс» в левом нижнем углу приложения Spotify.
  Вы можете создать его самостоятельно или скачать этот.
  

• Назовите его SaveToYourLibraryIcon.png и поместите его в тот же каталог, что и ваш скрипт.

• Вот и все. Нажмите Ctrl+Shift+Win+F4 (измените это на то, что вы хотите), и активная песня будет добавлена в вашу библиотеку!