Добавить выбор слайсера на лист в списке - Excel VBA

Question

У меня есть сводная таблица с слайсером, в котором пользователь может сделать несколько выборов. Я пытаюсь перечислить выбранные значения в слайсере, чтобы затем их можно было объединить в другой ячейке с помощью CONCATENATE. Я использую код ниже.

В данный момент ячейки L5:L7 заполняются первым выбором, выполненным в слайсере, но не другими.

Я провел некоторое исследование и нашел возможное решение с помощью функции CUBESET, но я не могу заставить его работать в моей электронной таблице. Отсюда и попытка VBA. Кто-нибудь знает, что с ним не так?

    Sub City_Click()

Dim cache As Excel.SlicerCache
Set cache = ActiveWorkbook.SlicerCaches("Slicer_City")
Dim sItem As Excel.SlicerItem
For Each sItem In cache.SlicerItems

If sItem.Selected = True Then Range("L5").Value = sItem.Name
If sItem.Selected = True Then Range("L6").Value = sItem.Name
If sItem.Selected = True Then Range("L7").Value = sItem.Name

Next sItem

End Sub

Answer 1

Вот пользовательская функция, которую вы можете вызвать непосредственно из книги, которая делает это для вас, и ее можно запустить на любом типе слайсера, будь то «традиционная» сводная таблица, OLAP/PowerPivot сводная таблица или табличный слайсер. Просто поместите это в стандартный модуль кода, а затем в рабочей книге введите следующее:

= SlicerItems("Slicer_City")

Public Function SlicerItems(SlicerName As String, Optional sDelimiter As String = "|") As String

    Dim oSc As SlicerCache
    Dim oSi As SlicerItem
    Dim i As Long
    Dim lVisible As Long
    Dim sVisible() As String

    On Error Resume Next
    Application.Volatile
    Set oSc = ThisWorkbook.SlicerCaches(SlicerName)
    If Not oSc Is Nothing Then
        With oSc
            If .FilterCleared Then
                SlicerItems = "(All)"
            Else
                If .OLAP Then
                    SlicerItems = Join(.VisibleSlicerItemsList, sDelimiter)
                    SlicerItems = Replace(SlicerItems, .SourceName, "")
                    SlicerItems = Replace(SlicerItems, ".&[", "")
                    SlicerItems = Replace(SlicerItems, "]", "")
                Else

                    lVisible = .VisibleSlicerItems.Count
                    If .VisibleSlicerItems.Count = 1 Then
                        SlicerItems = .VisibleSlicerItems(1).Name
                    Else
                        ReDim sVisible(1 To lVisible)
                        For i = 1 To lVisible
                            sVisible(i) = .VisibleSlicerItems(i).Name
                        Next i
                        SlicerItems = Join(sVisible, sDelimiter)
                    End If
                End If
            End If
        End With
    Else
        SlicerItems = SlicerName & " not found!"
    End If

End Function

А вот как это выглядит: