Это почему?
Можно найти ответ на вопрос « Почему это?"в статье Wildcards :
The * wildcard will match any sequence of characters
(0 or more, including NULL characters)
The ? wildcard will match a single character
(or a NULL at the end of a filename)
...
Правила подстановочных знаков
* Обычно соответствует любым 0 или более символам, за одним исключением (см. Следующее правило). Нежадный подстановочный знак может сопоставлять столько символов, сколько необходимо для соответствия оставшейся части маски.
*. В конце маски совпадает любой 0 или более символов, кроме {точка}. В действительности, правило применяется с любым количеством символов {точка} и {пробел} между * и терминалом {точка}. Регулярное выражение для этого термина "[*][. ]*[.]$"
? Совпадение 0 или один символ, кроме {точка}. Единственный раз, когда он соответствует 0 символам, это когда он соответствует концу имени или позиции перед точкой {точка}. Знак вопроса также может использоваться более одного раза, чтобы соответствовать более чем одному символу.
Смысл. Последняя точка в имени файла / папки разделяет базовое имя и расширение. Так
dir *. отображает все элементы без расширения иdir *.* отображает все элементы с расширением от нуля или более символов.
Строго говоря, dir *. отображает все элементы без точки (.) в имени. (Кстати, в статье MSDN, названии файлов, путей и пространств имен явно сказано, что « допустимо указывать точку в качестве первого символа имени ».)
Есть ли способ перечислить только файлы с точкой?
Я так не думаю. Однако есть обходной путь с подходящим регулярным выражением.
PowerShell (полнофункциональное решение, если используется в консоли Powershell):
:: PowerShell - no extension, full syntax
PowerShell -c "Get-ChildItem | Where-Object {$_.Name -match '^.[^\.]*$'}"
:: PowerShell - extension, alias syntax
PowerShell -c "dir | ? {$_.Name -match '^..*\...*$'}"
Cmd (только идея, может потребовать некоторой проработки):
:: CMD/batch - no extension
for /F "delims=" %%G in ('dir /OGN /B ^| findstr "^.[^\.]*$"') do @echo %%~tG %%~aG %%~zG %%~nxG
:: CMD/batch - extension
for /F "delims=" %%G in ('dir /OGN /B ^| findstr "^..*\...*$"') do @echo %%~tG %%~aG %%~zG %%~nxG
Приложение: бонус и объяснение
Интуитивно понятное предположение, что Name является объединенным BaseName а Extension не поддерживается. Следующий скрипт доказывает это, используя основные функции cmd и PowerShell , и странный ^..*\...*$ регулярное выражение получено из его результатов.
@ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion
set "_workingDirectory=%~1"
if "%_workingDirectory%"=="%tmp%\tests_SU_1193102" (
>NUL 2>&1 (
mkdir "%_workingDirectory%"
pushd "%_workingDirectory%"
rem make directories
mkdir .Fldr-Ext
mkdir aFldr-Ext
mkdir .Fldr.Ext
mkdir aFldr.Ext
rem create files
copy NUL .File-Ext
copy NUL aFile-Ext
copy NUL .File.Ext
copy NUL aFile.Ext
popd
)
) else if "%_workingDirectory%"=="" set "_workingDirectory=%CD%"
pushd "%_workingDirectory%"
set "_first=ItemName Attributes BaseName Extension"
echo ON
:: dir /OGN | findstr "Ext$"
for /F "delims=" %%G in ('dir /OGN /B') do @((if defined _first (echo %_first%&echo(&set "_first="))&echo %%~nxG %%~aG %%~nG %%~xG)
:: Get-ChildItem | Select-Object -Property Mode, BaseName, Extension, Name
PowerShell -c "dir | select -pr Name, Mode, BaseName, Extension | sort -pr @{Expression='Mode';Descending=$true}, @{Expression='Name';Descending=$false}"
Выход:
==> D:\bat\BaseName_vs_Extension.bat "%tmp%\tests_SU_1193102"
==> for /F "delims=" %G in ('dir /OGN /B') do @((if defined _first (echo ItemName Attributes BaseName Extension & echo( & set "_first=" ) ) & echo %~nxG %~aG %~nG %~xG )
ItemName Attributes BaseName Extension
.Fldr.Ext d---------- .Fldr .Ext
.Fldr-Ext d---------- .Fldr-Ext
aFldr.Ext d---------- aFldr .Ext
aFldr-Ext d---------- aFldr-Ext
.File.Ext --a-------- .File .Ext
.File-Ext --a-------- .File-Ext
aFile.Ext --a-------- aFile .Ext
aFile-Ext --a-------- aFile-Ext
==> PowerShell -c "dir | select -pr Name, Mode, BaseName, Extension | sort -pr @{Expression='Mode';Descending=$true}, @{Expression='Name';Descending=$false}"
Name Mode BaseName Extension
---- ---- -------- ---------
.Fldr.Ext d----- .Fldr.Ext .Ext
.Fldr-Ext d----- .Fldr-Ext .Fldr-Ext
aFldr.Ext d----- aFldr.Ext .Ext
aFldr-Ext d----- aFldr-Ext
.File.Ext -a---- .File .Ext
.File-Ext -a---- .File-Ext
aFile.Ext -a---- aFile .Ext
aFile-Ext -a---- aFile-Ext
Сравните определение свойства BaseName , различного для файлов и папок:
PS D:\PShell> Get-ChildItem | Get-Member -Name BaseName | Format-List -property TypeName, Definition
TypeName : System.IO.DirectoryInfo
Definition : System.Object BaseName {get=$this.Name;}
TypeName : System.IO.FileInfo
Definition : System.Object BaseName {get=if ($this.Extension.Length -gt
0){$this.Name.Remove($this.Name.Length -
$this.Extension.Length)}else{$this.Name};}
Мой оригинальный ответ был основан на непростительном недоразумении:
Читать dir /? , используйте dir /A:-D:
/A Displays files with specified attributes.
attributes D Directories R Read-only files
H Hidden files A Files ready for archiving
S System files I Not content indexed files
L Reparse Points - Prefix meaning not
Другой подход: применить регулярное выражение findstr как dir *.* | findstr /V "<.*>"
