Как эмулировать гиперключ в Windows 10 с помощью autohotkey

Question

Я перевожу свой рабочий процесс Mac в Windows. Одной вещью, без которой я не смог бы жить, является гипер-ключ, который является комбинацией Ctrl + Option + Shift + Cmd . Я использую приложение Karabiner , чтобы переназначить Capslock на этот Hyper ключ. Я слышал, что Autohotkey - это альтернатива для Карабинера для Windows . Не могли бы вы, ребята, помочь мне эмулировать эту функцию в Windows.

Мой идеальный результат:

• Capslock потому что я редко использую это
• Toggle Capslock выполнит клавишу ESC
• Удерживая Capslock вы выполните Ctrl + Alt + Shift + Windows . Например Capslock + C будет Ctrl+Alt+Shift+Windows+C

Спасибо заранее!

В попытке решить мою проблему я написал несколько строк кода, но это не работает вообще. Пожалуйста, помогите мне указать на мою ошибку:

;-----------------------------------------
; hyper key for windows
;=========================================

; --------------------------------------------------------------
; notes
; --------------------------------------------------------------
; ! = alt
; ^ = ctrl
; + = shift
; # = lwin|rwin
;
#NoEnv ; recommended for performance and compatibility with future autohotkey releases.
#UseHook
#InstallKeybdHook
#SingleInstance force

SendMode Input

;; deactivate capslock completely
SetCapslockState, AlwaysOff

;; remap capslock to hyper
;; if capslock is toggled, remap it to esc

Capslock::
    SendInput {Ctrl Down}{Alt Down}{Shift Down}{LWin Down}
    KeyWait, Capslock
    SendInput {Ctrl Up}{Alt Up}{Shift Up}{LWin Up}
    if (A_PriorKey = "Capslock") {
        SendInput {Esc}
    }
return

;; vim navigation with hyper
~^!+#h:: SendInput {Left}
~^!+#l:: SendInput {Right}
~^!+#k:: SendInput {Up}
~^!+#j:: SendInput {Down}

;; popular hotkeys with hyper
~^!+<#c:: SendInput ^{c}
~^!+<#v:: SendInput ^{v}

Результат:

• Toggle Capslock выполняет ESC
• Hold Capslock выполняет комбинацию клавиш Ctrl+Alt+Shift+Win
• Удержание Ctrl+Alt+Shift+Win с h, j, k, l, c, v работает как положено
• Однако Hold Capslock с h, j, k, l, c, v не работает

Answer 1

Спасибо за всех, кто пытается мне помочь, я разобрался с проблемой самостоятельно и хотел бы поделиться ею на случай, если кто-нибудь столкнется с этой проблемой.

#NoEnv ; recommended for performance and compatibility with future autohotkey releases.
#UseHook
#InstallKeybdHook
#SingleInstance force

SendMode Input

;; deactivate capslock completely
SetCapslockState, AlwaysOff

;; remap capslock to hyper
;; if capslock is toggled, remap it to esc

;; note: must use tidle prefix to fire hotkey once it is pressed
;; not until the hotkey is released
~Capslock::
    ;; must use downtemp to emulate hyper key, you cannot use down in this case 
    ;; according to http://bit.ly/2fLyHHI, downtemp is as same as down except for ctrl/alt/shift/win keys
    ;; in those cases, downtemp tells subsequent sends that the key is not permanently down, and may be 
    ;; released whenever a keystroke calls for it.
    ;; for example, Send {Ctrl Downtemp} followed later by Send {Left} would produce a normal {Left}
    ;; keystroke, not a Ctrl{Left} keystroke
    Send {Ctrl DownTemp}{Shift DownTemp}{Alt DownTemp}{LWin DownTemp}
    KeyWait, Capslock
    Send {Ctrl Up}{Shift Up}{Alt Up}{LWin Up}
    if (A_PriorKey = "Capslock") {
        Send {Esc}
    }
return

;; vim navigation with hyper
~Capslock & h:: Send {Left}
~Capslock & l:: Send {Right}
~Capslock & k:: Send {Up}
~Capslock & j:: Send {Down}

;; popular hotkeys with hyper
~Capslock & c:: Send ^{c}
~Capslock & v:: Send ^{v}