Пакетный файл для замены строки в имени файла и расширении

Question

Я пытаюсь написать простой, небольшой и гибкий пакетный файл, который легко изменить для разных производителей, который будет просматривать список файлов gerber, созданных в Proteus, и переименовывать их соответствующим образом.

Этот набор предназначен для Seeed Studio.

У меня проблема в том, что исправляется только расширение, мне нужно заменить всю строку.

т.е. "Схема - CADCAM Bottom Copper.TXT "становится" Circuit.ГБЛ "и т.д.

В настоящее время "Автодром" - CADCAM Bottom Copper.TXT "становится" Circuit - CADCAM Bottom Copper.GBL»

Спасибо за помощь,

Haydan

@echo off
Setlocal enabledelayedexpansion

REM Check all files are present and rename

set MISSING=0
call :CheckFile " - CADCAM Bottom Copper.TXT", ".GBL"
call :CheckFile " - CADCAM Bottom Copper", "-"
call :CheckFile " - CADCAM Bottom Silk Screen.TXT", ".GBO"
call :CheckFile " - CADCAM Bottom Solder Resist.TXT", ".GBS"
call :CheckFile " - CADCAM Drill.TXT", ".TXT"
call :CheckFile " - CADCAM Mechanical 1.TXT", ".GKO"
call :CheckFile " - CADCAM Top Copper.TXT", ".GTL"
call :CheckFile " - CADCAM Top Silk Screen.TXT", ".GTO"
call :CheckFile " - CADCAM Top Solder Resist.TXT", ".GTS"
REM if exist "Internal Plane 1.ger" call :CheckFile "Internal Plane 2.ger", ""

if %MISSING% EQU 0 (
    echo Success - all files found!
    pause
    goto :eof
) else (
    echo %MISSING% file^(s^) missing.
    pause
    goto :eof
)
REM Rename as found or flag erro

:CheckFile
if not exist *%1 (
    echo ERROR: Missing %1!
    set /a MISSING=%MISSING% + 1
) else (
    echo %1
    echo %2
    ren *%1 *%2
)

Answer 1

Далее : процедура :CheckFile должна сделать работу:

:CheckFile
set "_string=%~1"
if not exist *%1 (
    echo ERROR: Missing %1!
    set /a MISSING+=1
) else (
    for /F "delims=" %%G in ('dir /B "*%~1"') do (
        set "_fileA=%%~G"
        set "_fileB=!_fileA:%_string%=!"
        rem next `rename` command is merely ECHOed for debugging purposes
        ECHO ren "%%~G" "!_fileB!%~2"
    )
)
goto :eof

Примечание: команда rename просто ECHOed для целей отладки в приведенном выше фрагменте кода; удалить ведущий ECHO (используйте ren "%%~G" "!_fileB!%~2") не раньше, чем отлажено!

Выход:

==> D:\bat\SU\1119379.bat
ren "Circ #2 - CADCAM Bottom Copper.TXT" "Circ #2.GBL"
ren "Circuit - CADCAM Bottom Copper.TXT" "Circuit.GBL"
ren "Circuit - CADCAM Bottom Copper" "Circuit-"
ERROR: Missing " - CADCAM Bottom Silk Screen.TXT"
ERROR: Missing " - CADCAM Bottom Solder Resist.TXT"
ERROR: Missing " - CADCAM Drill.TXT"
ERROR: Missing " - CADCAM Mechanical 1.TXT"
ERROR: Missing " - CADCAM Top Copper.TXT"
ERROR: Missing " - CADCAM Top Silk Screen.TXT"
ERROR: Missing " - CADCAM Top Solder Resist.TXT"
7 file(s) missing.
Press any key to continue . . .

Ресурсы (требуется чтение, не полностью):

• (справочник по командам) Индекс AZ командной строки Windows CMD
• (дополнительные особенности) Синтаксис командной строки Windows CMD Shell
• (%~G , %~1 и т.д. Специальная страница) Аргументы командной строки (параметры)
• (set "_fileB=!_fileA:%_string%=!" И т.д.) Переменная Редактировать / Заменить