Как заставить Блокнот войти в полноэкранный режим?

Question

Блокнот Windows - мой любимый текстовый ридер в Windows 10. Это занимает очень мало оперативной памяти, позволяет мне настроить шрифт, и имеет чистый интерфейс. Как сделать так, чтобы он работал на полном экране, как TextEdit на MacOS?

Answer 1

Блокнот не предлагает полноценную полноэкранную функцию.

Единственная альтернатива, о которой я могу подумать, это:

Если вы хотите, чтобы блокнот запоминал эту позицию при каждом открытии (либо при запуске блокнота, либо при открытии файла через проводник), убедитесь, что вы перетаскиваете края окна и не используете кнопку «Развернуть». Кроме того, когда вы перетаскиваете края и окна привязываются к окну (оно вдруг оказывается идеально по высоте, ширине или обоим), окна также не запоминают его.

Вы можете видеть, что это происходит, если вокруг курсора мыши отображается круг. Единственный способ не привязать его - это либо отключить функцию, либо изменить размер окна пиксель за пикселем. Таким образом, вы изменяете его размер примерно на 20 пикселей от границы, затем отпускаете кнопку мыши. Затем вы нажимаете и перетаскиваете несколько пикселей одновременно и снова отпускаете. Таким образом, окна не запустят функцию привязки, и вы можете изменить ее размер, чтобы он полностью соответствовал экрану.

После этого закройте блокнот, и настройки запомнятся.

Answer 2

Я разработал сценарий в AutoHotkey для этого только сейчас, спасибо за интересную идею. Я тестировал его только в Windows 7, поэтому надеюсь, что он работает и в Windows 10. Он использует две комбинации клавиш для включения / выключения полноэкранного режима. Он изменяет размеры окон, немного расширяет его за пределы экрана, чтобы скрыть полосы прокрутки, и удаляет строку меню и строку заголовка.

#IfWinActive, ahk_class Notepad
^q:: ;notepad fullscreen on
WinGet, hWnd, ID, A
WinGetClass, vWinClass, ahk_id %hWnd%
if vWinClass not in Notepad
Return

WinGet, vWinMinMax, MinMax, ahk_id %hWnd%
if (vWinMinMax = 1) ;1=max/0=res/1=min
WinRestore, ahk_id %hWnd%

if (hMenu%hWnd% = "")
hMenu%hWnd% := DllCall("GetMenu", "uint", hWnd)

if (vPos%hWnd% = "") OR (vWinMinMax = 0)
{
WinGetPos, vPosX, vPosY, vPosW, vPosH, ahk_id %hWnd%
vPos%hWnd% := vPosX "," vPosY "," vPosW "," vPosH
}

WinSet, Style, -0xC00000, ahk_id %hWnd% ;hide title bar
DllCall("SetMenu", "uint", hWnd, "uint", 0) ;hide menu bar
WinMove, ahk_id %hWnd%, , 0, 0, % A_ScreenWidth + 20, % A_ScreenHeight + 20
Return

;==================================================

^w:: ;notepad fullscreen off
WinGet, hWndZ, ID, A
WinGetClass, vWinClassZ, ahk_id %hWndZ%
if vWinClassZ not in Notepad
Return

hMenuZ := hMenu%hWndZ%
if (hMenuZ = "")
Return
vPosZ := vPos%hWndZ%

WinSet, Style, +0xC00000, ahk_id %hWndZ% ;show title bar
DllCall("SetMenu", "uint", hWndZ, "uint", hMenuZ) ;show menu bar
StringSplit, vPosZ, vPosZ, `,
WinMove, ahk_id %hWnd%, , %vPosZ1%, %vPosZ2%, %vPosZ3%, %vPosZ4%
Return
#IfWinActive