Добавить дату и время для файлов в пакетном режиме

Question

Этот код читает файлы из папки и назначает всем одинаковое время.

Код:

@echo off
set datetime=%date:~4,2%%date:~7,2%%date:~10,4%_%time:~0,2%%time:~3,2%%time:~6,2%
for /f "delims=" %%x in ('dir /b /s D:\v\*.*') do (
  echo %%~dpnx_%datetime%%%~xx>>C:\Users\TechMadmin\Desktop\scripts\a.txt
)
move /y C:\Users\TechMadmin\Desktop\scripts\a.txt C:\Users\TechMadmin\Desktop\scripts\b.txt

Выход:

a_08042016_095244.txt 
a_08042016_095244.txt

Мое требование - иметь разную дату и время для двух файлов, чтобы мы могли различать их с изменениями в миллисекундах.

Требуемый выход:

a_08042016_095244.txt 
a_08042016_095252.txt

Answer 1

Мое требование - иметь разную дату и время для двух файлов.

так что мы можем дифференцироваться с изменением в миллисекундах.

Вы можете использовать время создания файла, чтобы получить уникальное значение даты / времени, поскольку маловероятно, что два файла с одинаковым именем будут иметь одинаковое время создания.

test.bat:

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%x in ('dir /a-d /b /s f:\v\*.*') do (
  rem use file creation time to get unique timestamp.
  rem need to double up the \ for the wmic query.
  set _name=%%x
  set _name=!_name:\=\\!
  for /f %%t in ('wmic datafile where name^="!_name!" get creationdate ^| findstr /brc:[0-9]') do (
    set _datetime=%%t
    )
  rem strip last 4 characters as always the same
  echo %%~dpnx_!_datetime:~0,-4!%%~xx>>out.log
)
endlocal

Пример использования:

F:\test>dir /a-d /b /s f:\v
f:\v\A\a.txt
f:\v\A\B\a.txt
f:\v\A\C\a.txt
f:\v\A\C\D\a.txt

F:\test>test

F:\test>type out.log
f:\v\A\a_20160804231753.551948.txt
f:\v\A\B\a_20160804231800.344348.txt
f:\v\A\C\a_20160804231803.581548.txt
f:\v\A\C\D\a_20160804231807.072814.txt

Ваш пакетный файл изменен соответствующим образом:

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%x in ('dir /a-d /b /s d:\v\*.*') do (
  rem use file creation time to get unique timestamp.
  rem need to double up the \ for the wmic query.
  set _name=%%x
  set _name=!_name:\=\\!
  for /f %%t in ('wmic datafile where name^="!_name!" get creationdate ^| findstr /brc:[0-9]') do (
    set _datetime=%%t
    )
  rem strip last 4 characters as always the same
  echo %%~dpnx_!_datetime:~0,-4!%%~xx>>C:\Users\TechMadmin\Desktop\scripts\a.txt
)
move /y C:\Users\TechMadmin\Desktop\scripts\a.txt C:\Users\TechMadmin\Desktop\scripts\b.tx
endlocal

---

Дальнейшее чтение

• Индекс AZ командной строки Windows CMD - Отличный справочник по всем вопросам, связанным с командной строкой Windows.
• dir - Показать список файлов и подпапок.
• enabledelayedexpansion - отложенное расширение приведет к тому, что переменные будут расширяться во время выполнения, а не во время анализа.
• for /f - команда цикла: для набора файлов - условно выполнить команду для каждого элемента.
• Редактирование и замена переменных - Редактирование и замена символов, назначенных строковой переменной.
• переменные - извлечение части переменной (подстроки).
• wmic - команда инструментария управления Windows.