Потеря символов при копировании и вставке в командный файл через VBA

Question

В настоящее время я использую следующий код VBA для копирования и вставки диапазона данных в файл Excel для создания пакетного файла. Я сталкиваюсь со следующими проблемами:

1. Котировки размещаются вокруг содержимого отдельных ячеек
2. Я теряю возвращение персонажа

Вот что копируют мои данные, каждую строку, указанную ниже, необходимо скопировать в другую строку в командном файле:

@ftp -i -s:"%~f0"&GOTO:EOF
open ecggwprd.uhc.com
if1**79
W88***3k
bin
put \\Nas00233pn\ACP_Finance_Ops\FTP\Ced.201602.zip  /cedarhill/Ced.201602.zip
!ping -n 30 0.0.0.0 > NULL
CD /ced
dir Q__C_

Кто-нибудь знает, как я могу изменить свой код VBA, чтобы исправить эти элементы?

Вот копия моего кода:

Sub savebat()

Dim wbSource As Workbook
Dim wsSource As Worksheet
Dim wbDest As Workbook
Dim fName As String

Set wbSource = ActiveWorkbook
Set wsSource = ActiveSheet
Set wbDest = Workbooks.Add

wsSource.Range("A1:A51").Copy

'----------------------------
'Save in new workbook
wbDest.Worksheets(1).Cells(1, 1).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
Application.CutCopyMode = False

Application.CutCopyMode = False

'Get file name and location from user
fName = Application.GetSaveAsFilename(FileFilter:="bat (*.bat), *.bat", Title:="Save As")
If fName = "" Then Exit Sub '//user cancelled

'Save new bat file
wbDest.SaveAs fName, FileFormat:=xlText

wbDest.Close SaveChanges:=True
'----------------------------

End Sub

Answer 1

Просто пишите в файл, а не проходите через другой ББ.

Option Explicit

Sub CreateBatch()
    Dim myPathTo As String
    myPathTo = "C:\path\to\mybatch.bat"
    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Dim batchFile As Object
    Set batchFile = fso.CreateTextFile(myPathTo)

    Dim lastRow As Long
    lastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Dim i As Long

        For i = 1 To lastRow
            batchFile.write Cells(i, 1) & vbNewLine
        Next
        batchFile.Close
    Set fso = Nothing
    Set batchFile = Nothing
End Sub